Public Class frmGridRowNumbers
 
    'Datenquelle, Bindung und Control 
    Dim dt As New DataTable
    Dim bs As New BindingSource
    Dim WithEvents dgv As New DataGridView With {.Parent = Me}
 
 
    Dim filtered As Boolean = False 'Rechte Maustaste filtert Daten 
 
 
 
    Private Sub frmGridRowNumbers_Load(sender As System.Object, _
                                e As System.EventArgs) Handles MyBase.Load
 
        'Eine Demospalte mit Daten erstellen
 
        dt.Columns.Add("Numbers", GetType(Decimal))
        For i As Integer = 0 To 99
            dt.Rows.Add(Rnd())
        Next i
 
        bs.DataSource = dt
 
        With dgv
            .DataSource = bs
 
            'Rowheader breit genug einstellen    
            .RowHeadersWidth = 80
 
            'Ausrichtung/Format der numerischen Werte
            .Columns(0).DefaultCellStyle.Alignment = _
                DataGridViewContentAlignment.MiddleRight
            .Columns(0).DefaultCellStyle.Format = "0.0000"
        End With
 
    End Sub
 
 
 
    Private Sub dgv_MouseDown(sender As Object, _
        e As System.Windows.Forms.MouseEventArgs) Handles dgv.MouseDown
        If e.Button = Windows.Forms.MouseButtons.Right Then
 
            'Filter-Beispiel
 
            filtered = Not filtered
            If filtered Then
                bs.Filter = "Numbers > 0.5"
            Else
                bs.Filter = String.Empty
            End If
        End If
    End Sub
 
 
 
    Private Sub dgv_RowPostPaint(sender As Object, _
        e As System.Windows.Forms.DataGridViewRowPostPaintEventArgs) _
        Handles dgv.RowPostPaint
 
        Using b As New SolidBrush(dgv.RowHeadersDefaultCellStyle.ForeColor)
            With e.Graphics
                'Zählung ab Zeile 1
                Dim rowindex As String = (e.RowIndex + 1).ToString
 
                'Ausrichtung der Zeilennummern in der Headerspalte 
                Dim sz As SizeF = _
                    .MeasureString(rowindex, e.InheritedRowStyle.Font, _
                    dgv.RowHeadersWidth)
 
                Dim posx As Single = _
                    e.RowBounds.Location.X + dgv.RowHeadersWidth - sz.Width - 5
 
                'aktuelle Zeilennummer zeichnen  
                .DrawString(rowindex, e.InheritedRowStyle.Font, b, _
                                      posx, e.RowBounds.Location.Y + 4)
            End With
        End Using
    End Sub
End Class