Public Class frmGridCreateRows
 
    Dim WithEvents dgv As New DataGridView With _
        {.Parent = Me, .Dock = DockStyle.Fill}
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
    Private Sub frmGridCreatRowsLoad(sender As System.Object, _
                e As System.EventArgs) Handles MyBase.Load
 
        'Testdaten
        With dt.Columns
            .Add("W1")
            .Add("Addresse")
            .Add("Umbruch")
        End With
 
        With dt.Rows
            .Add("Meike", "Hilbertshausen", "")
            .Add("Hubert", "Groningen", "")
        End With
 
        bs.DataSource = dt
        dgv.DataSource = bs
    End Sub
 
 
    Private Sub dgv_CellEndEdit(sender As Object, _
        e As System.Windows.Forms.DataGridViewCellEventArgs) _
        Handles dgv.CellEndEdit
 
        If e.RowIndex < 0 Then Return
        If Not e.ColumnIndex = 0 Then Return
 
        Dim vl As Object = _
           dgv.Rows(e.RowIndex).Cells(e.ColumnIndex).Value
        If vl Is Nothing OrElse IsDBNull(vl) Then Return
 
        Dim str As String = vl.ToString
        If str.Length > 10 Then
            'neue Zeile erstellen, füllen und anzeigen
            Dim str2 As String = str.Substring(10)
 
            str = str.Substring(0, 10)
            dgv.Rows(e.RowIndex).Cells(e.ColumnIndex).Value = str
 
            Dim umbruch As String = _
            dgv.Rows(e.RowIndex).Cells("Addresse").Value.ToString
 
            Dim newrow As DataRow = CType(bs.AddNew, DataRowView).Row
            newrow.ItemArray = {str2, "", umbruch}
 
            bs.EndEdit()
 
            'Anzeige erzwingen
            dgv.Refresh()
        End If
 
    End Sub
 
End Class