'Die Klasse
Public Structure LElement
 
    Public Property SpalteA As String
    Public Property SpalteB As String
    Public Property SpalteC As String
 
End Structure
 
'Der Comparer
Public Class HierarchicalComparer
    Implements IComparer(Of LElement)
 
    Private _compareorder() As String
 
    Public Property CompareOrder() As String()
        Set(value As String())
            _compareorder = value
        End Set
        Get
            Return _compareorder
        End Get
    End Property
 
    Private Function GetValues(el As LElement) As String()
        Dim lst As New List(Of String)
        With el
            For i As Integer = 0 To _compareorder.Length - 1
 
                Select Case _compareorder(i)
                    Case "SpalteA"
                        lst.Add(.SpalteA)
                    Case "SpalteB"
                        lst.Add(.SpalteB)
                    Case "SpalteC"
                        lst.Add(.SpalteC)
                    Case Else
                        Throw New InvalidOperationException _
                           ("Unbekannte Sortierspalte")
                End Select
            Next
        End With
        Return lst.ToArray
    End Function
 
    Public Function Compare(x As LElement, y As LElement) As Integer _
        Implements System.Collections.Generic.IComparer(Of LElement).Compare
 
        Dim xe() As String = GetValues(x)
        Dim ye() As String = GetValues(y)
 
        For i As Integer = 0 To xe.Length - 1
            Dim cr As Integer = xe(i).CompareTo(ye(i))
            If Not cr = 0 Then Return cr
        Next i
        Return 0
    End Function
End Class

        Dim l As New List(Of LElement)
 
        For i As Integer = 1 To 30
            Dim it As New LElement
            it.SpalteA = Chr(i + 65)
            it.SpalteB = Chr(90 - i)
            it.SpalteC = Chr(CInt(Rnd() * 10 + 65))
            l.Add(it)
        Next i
 
        Dim hc As New HierarchicalComparer
        hc.CompareOrder = {"SpalteC", "SpalteB"}
 
        l.Sort(hc)