Public Class frmAniIcon2
 
    <System.Runtime.InteropServices.DllImport("User32.dll")> _
    Private Shared Function DestroyIcon(hIcon As System.IntPtr) As Boolean
    End Function
 
    Private Structure gifdaten
        Dim path As String
        Dim image As Image
        Dim dimension As System.Drawing.Imaging.FrameDimension
        Dim framecount As Integer
        Dim currentframe As Integer
    End Structure
 
    Dim gd As New gifdaten
    Dim ico As Icon
 
    Dim WithEvents tim As New Timer With _
        {.Enabled = False, .Interval = 200}
 
 
    Private Sub frmAniIcon2_Load(sender As System.Object, _
                e As System.EventArgs) Handles MyBase.Load
 
        With gd
            .path = <Pfad/Name eines animierten GIF angeben!>
            If IO.File.Exists(.path) Then
                .image = Image.FromFile(.path)
                .dimension = _
                New Imaging.FrameDimension(.image.FrameDimensionsList(0))
                .framecount = .image.GetFrameCount(.dimension)
            End If
        End With
 
    End Sub
 
 
    Private Sub tim_Tick(sender As Object, _
                         e As System.EventArgs) Handles tim.Tick
 
        If ico IsNot Nothing Then DestroyIcon(ico.Handle)
 
        With gd
            If .image Is Nothing Then Exit Sub
 
            .currentframe += 1
            If .currentframe >= .framecount Then .currentframe = 0
 
            .image.SelectActiveFrame(.dimension, .currentframe)
 
            Using bmp As Bitmap = DirectCast(.image.Clone(), Bitmap)
                Dim icoptr As System.IntPtr = bmp.GetHicon
                ico = Icon.FromHandle(icoptr)
            End Using
        End With
 
        Me.Icon = ico
 
    End Sub
 
 
    Private Sub frmAniIcon_Resize(sender As Object, _
                                  e As System.EventArgs) Handles Me.Resize
        tim.Enabled = Me.WindowState = FormWindowState.Minimized
    End Sub
End Class