Public Class frmColumnBox
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
 
    'Dictionary für das Ansprechen der Textboxen im Code per Columnname
    Dim tb_dic As New Dictionary(Of String, TextBox)
 
 
    Dim WithEvents btnNext As New Button With _
       {.Parent = Me, .Text = "Next"}
 
 
    Private Sub frmColumnBox_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Me.Height = 350 : Me.Width = 300
 
        'Testdaten erzeugen
        For i As Integer = 0 To 7
            dt.Columns.Add("SP_" & CStr(i))
        Next i
        For i As Integer = 0 To 99
            Dim items(7) As String
            For k As Integer = 0 To 7
                items(k) = "SP_" & CStr(i) & " R_" & CStr(k)
            Next k
            dt.Rows.Add(items)
        Next i
 
        bs.DataSource = dt
 
        'Columnboxen erzeugen
        CreateColumnBoxes(bs)
 
        'Ansprechen einer ColumnBox im Code
        tb_dic(dt.Columns(3).ColumnName).Text = "changed"
    End Sub
 
 
    Private Sub ColumnBox_TextChanged(ByVal sender As Object, _
        e As EventArgs)
 
        Dim tb As TextBox = CType(sender, TextBox)
        'MsgBox(tb.Name & ": Text ist geändert worden")
    End Sub
 
 
    Private Sub CreateColumnBoxes(ByVal bs As BindingSource)
 
        'Erstellen von gebundenen Textboxen zu den Table-Spalten
 
        Dim dt As DataTable = CType(bs(0), DataRowView).Row.Table
 
        Dim tb_top As Integer = 50
        Dim tb_width As Integer = 200
 
        For i As Integer = 0 To dt.Columns.Count - 1
            Dim cn As String = dt.Columns(i).ColumnName
            Dim tb As New TextBox With {.Parent = Me, .Name = cn, _
                        .Top = i * 30 + tb_top, .Width = tb_width}
            Dim bn As New Binding("Text", bs, cn)
            tb.DataBindings.Add(bn)
            AddHandler tb.TextChanged, AddressOf ColumnBox_TextChanged
            tb_dic.Add(cn, tb)
        Next i
    End Sub
 
    Private Sub btnNext_Click(sender As Object, _
        e As System.EventArgs) Handles btnNext.Click
 
        If bs.Position < bs.Count - 1 Then
            bs.Position += 1
        Else
            bs.Position = 0
        End If
    End Sub
End Class