Imports System
Imports System.Windows.Forms
 
Public Class ListBoxSelectMultiExtended
    Inherits Windows.Forms.ListBox
 
    Dim _pressedkey As Keys
    Dim _lastselectedindex As Integer
 
 
    Public Sub New()
        MyBase.SelectionMode = Windows.Forms.SelectionMode.MultiExtended
        _lastselectedindex = -1
    End Sub
 
 
    Public Shadows Property Selectionmode() As Windows.Forms.SelectionMode
        Set(value As Windows.Forms.SelectionMode)
            MyBase.SelectionMode = Windows.Forms.SelectionMode.MultiExtended
        End Set
        Get
            Return MyBase.SelectionMode
        End Get
    End Property
 
 
    Protected Overrides Sub OnKeyDown(e As System.Windows.Forms.KeyEventArgs)
        MyBase.OnKeyDown(e)
        _pressedkey = e.KeyCode
    End Sub
 
 
    Private Shadows Sub SelectedIndexChanged(sender As Object, _
        e As System.EventArgs) Handles MyBase.SelectedIndexChanged
        FindIndexToShow()
    End Sub
 
 
    Public ReadOnly Property LastSelectedIndex() As Integer
        Get
            Return _LastSelectedIndex
        End Get
    End Property
 
 
    Private Sub FindIndexToShow()
 
        Static oldindices() As Integer
        Dim found As Boolean, k As Integer
 
        With Me.SelectedIndices
            If .Count = 0 Then
                _lastselectedindex = -1
            ElseIf .Count = 1 Then
                _lastselectedindex = .Item(0)
            ElseIf oldindices IsNot Nothing Then
                For i As Integer = 0 To .Count - 1
                    found = False
                    For k = 0 To oldindices.Length - 1
                        If .Item(i) = oldindices(k) Then found = True : Exit For
                    Next k
                    If Not found Then
                        'neu markiertes Item gefunden
                        _lastselectedindex = .Item(i) : Exit For
                    End If
                Next i
 
                If found Then
                    For i As Integer = 0 To oldindices.Length - 1
                        found = False
                        For k = 0 To .Count - 1
                            If .Item(k) = oldindices(i) Then found = True : _
                              Exit For
                        Next k
                        If Not found Then
                            'gelöschtes Item gefunden
                            If _pressedkey = Keys.Up And k > 0 Then
                                'Item davor einstellen
                                _lastselectedindex = .Item(k - 1)
                            ElseIf _pressedkey = Keys.Down And k < .Count - 1 _
                              Then
                                'Item danach einstellen 
                                _lastselectedindex = .Item(k + 1)
                            Else
                                _lastselectedindex = Me.SelectedIndex
                            End If
                            Exit For
                        End If
                    Next i
                End If
            End If
 
            If .Count > 0 Then
                'aktuelle Auswahl speichern
                ReDim oldindices(.Count - 1)
                Me.SelectedIndices.CopyTo(oldindices, 0)
            Else
                oldindices = Nothing
            End If
        End With
    End Sub
End Class