''' <summary>Suche im Text nach dem Listenindex des ersten Wortes, 
'''  das in der Wortliste enthalten ist</summary>
''' <param name="Text">zu durchsuchender Text</param>
''' <param name="SplitStrings">"Trennzeichen zwischen den Worten im Text</param>
''' <param name="wordlist">Liste mit Worten, nach denen zu suchen ist</param>
''' <param name="Ignorecase">Groß-/Kleinschreibung bei Suche ignorieren?</param>
''' <returns>Listen-Index des ersten gefundenen Wortes (oder -1) </returns>
Public Function IndexOfWord(ByVal text As String, _
                            ByVal wordlist As Collections.Generic.List(Of _
                            String), _
                   Optional ByVal SplitStrings() As String = Nothing, _
                   Optional ByVal Ignorecase As Boolean = False) As Integer
 
    'Eingaben prüfen
    If wordlist Is Nothing OrElse wordlist.Count = 0 Then Return -1
    If String.IsNullOrEmpty(text) Then Return -1
 
    If SplitStrings Is Nothing OrElse SplitStrings.Count = 0 Then
       SplitStrings = {" "} 'Default-Trennzeichen zwischen Worten
    End If
 
    'Text und Wortliste für den internen Gebrauch umsetzen
    Dim ilist As New Collections.Generic.List(Of String)
    Dim itext As String = ""
 
    If Ignorecase Then
       itext = text.ToLower
       For i As Integer = 0 To wordlist.Count - 1
          ilist.Add(wordlist(i).ToLower)
       Next i
    Else
       itext = text
       ilist = wordlist       
   End If
 
   'Worte im Text anhand der Trennzeichen ermitteln
   Dim iwords As New Collections.Generic.List(Of String) _
        (itext.Split(SplitStrings, StringSplitOptions.RemoveEmptyEntries))
 
   'die Worte im Text prüfen
   Dim idx As Integer
   For Each wrd As String In iwords
       'Suche nach dem Wortlisten-Index von wrd
       idx = ilist.IndexOf(wrd)
       If idx > -1 Then Return idx 'wrd gefunden
   Next wrd
 
   Return -1 'kein Wort aus dem Text in der Wort-Liste gefunden
End Function