Public Class TableHelpers
 
    ''' <summary>Kopieren einer Datatable mit Spaltenauswahl</summary>
    ''' <param name="source">zu kopierende Datztable</param>
    ''' <param name="columnnames">Namen der zu kopierenden Spalten</param>
    Public Shared Function CopyTable(ByVal source As DataTable,
                      ByVal columnnames() As String) As DataTable
 
        If source Is Nothing Or columnnames Is Nothing Then Return Nothing
 
        Dim destination As New DataTable
 
        With source
            For i As Integer = 0 To .Columns.Count - 1
                If Contains(columnnames, .Columns(i).ColumnName) Then
                    destination.Columns.Add(CopyColumn(.Columns(i)))
                End If
            Next i
 
            For r As Integer = 0 To .Rows.Count - 1
                Dim row As DataRow = destination.NewRow
                Dim cd As Integer = -1
                For c As Integer = 0 To .Columns.Count - 1
                    If Contains(columnnames, .Columns(c).ColumnName) Then
                        cd += 1
                        row(cd) = .Rows(r)(c)
                    End If
                Next c
                destination.Rows.Add(row)
            Next r
        End With
 
        Return destination
    End Function
 
 
    ''' <summary>Kopieren einer Datacolumn</summary>
    ''' <param name="column">zu kopierende Datacolumn</param>
    Public Shared Function CopyColumn(ByVal column As DataColumn) As DataColumn
 
        If column Is Nothing Then Return Nothing
 
        Dim c As New DataColumn
        With column
            c.AllowDBNull = .AllowDBNull
            c.ColumnName = .ColumnName
            c.Caption = .Caption
            c.DateTimeMode = .DateTimeMode
            c.DataType = .DataType
            c.DefaultValue = .DefaultValue
            c.MaxLength = .MaxLength
            c.ReadOnly = .ReadOnly
            c.Unique = .Unique
        End With
 
        Return c
    End Function
 
 
    Private Shared Function Contains(ByVal arr() As String, _
             tofind As String) As Boolean
 
        For Each item As String In arr
            If item.Trim.ToUpper = tofind.Trim.ToUpper Then Return True
        Next item
        Return False
    End Function
 
End Class