Public Class frmInvokeDemo_
    Inherits System.Windows.Forms.Form
 
    Private Sub InitializeComponent()
        Me.SuspendLayout()
        Me.ClientSize = New System.Drawing.Size(292, 273)
        Me.Name = "frmInvokeDemo_"
        Me.ResumeLayout(False)
    End Sub
 
 
    Private WithEvents button1 As New Button With _
    {.Parent = Me, .Text = "Start"}
 
    Private label_progress As New Label With _
        {.Parent = Me, .Top = 50, .BackColor = Color.White, .Width = 120}
 
    Private Delegate Sub SetTextToLabel_ProgressDelegate _
        (ByVal strTextIN As String)
 
    Private Thread_Download As System.Threading.Thread = Nothing
 
    Private dld As DownloadHelpers
 
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As  _
      System.EventArgs) Handles button1.Click
 
        dld = New DownloadHelpers
        dld.DisplayForm = Me
 
        Thread_Download = New System.Threading.Thread(AddressOf _
          dld.Thread_Download_Routine)
 
        Thread_Download.Priority = _
            Threading.ThreadPriority.BelowNormal
 
        Thread_Download.Start()
    End Sub
 
 
    Public Sub SetProgressText(ByVal strTextIN As String)
 
        If Me.InvokeRequired Then
            Me.Invoke(New SetTextToLabel_ProgressDelegate(AddressOf _
              SetText), New Object() {strTextIN})
        Else
            SetText(strTextIN)
        End If
    End Sub
 
 
    Private Sub SetText(ByVal strTextIN As String)
        With label_progress
            .Text = strTextIN
            .Refresh()
        End With
    End Sub
 
 
    Private Sub frmInvokeDemo__Load(sender As Object, e As System.EventArgs) _
        Handles Me.Load
 
        SetProgressText("Press Button To Start")
    End Sub
End Class
 
 
 
Class DownloadHelpers
 
    Private _Displayform As frmInvokeDemo_
 
    ''' <summary>Formular zur Anzeige der Informationen</summary>
    Public Property DisplayForm As frmInvokeDemo_
        Set(value As frmInvokeDemo_)
            _Displayform = value
        End Set
        Get
            Return _Displayform
        End Get
    End Property
 
 
    Public Sub Thread_Download_Routine()
 
        'Simulation eines Download-Vorgangs
        Dim zmax, z As Integer, text As String
        zmax = 10
 
        Try
            Do
                Threading.Thread.Sleep(1000)
 
                z += 1
 
                If _Displayform IsNot Nothing Then
                    If z < zmax Then
                        text = "Durchgang: " & z.ToString
                    Else
                        text = "Downloads beendet"
                    End If
                    _Displayform.SetProgressText(text)
                End If
            Loop While z < zmax
        Catch ex As Exception
        End Try
    End Sub
 
End Class