Public Class frmDGVSwap
 
    'Datenklasse mit Vergleichs-Schnittstelle für Sortieren
    Private Class data
        Implements IComparable(Of data)
        Public Property Daten As String
        Public Property satzposition As Integer
 
        Public Function CompareTo(other As data) As Integer _
            Implements System.IComparable(Of data).CompareTo
 
            If Me.satzposition < other.satzposition Then Return -1
            If Me.satzposition = other.satzposition Then Return 0
            Return 1
        End Function
    End Class
 
 
    'Liste, Bindung und Control
    Dim lst As New List(Of data)
    Dim bs As New BindingSource With {.RaiseListChangedEvents = True}
 
    Dim WithEvents dgv As New DataGridView With {.Parent = Me, .DataSource = bs}
 
 
    Private Sub frmDGVSwap_Load(sender As System.Object, e As System.EventArgs) _
      Handles MyBase.Load
 
        'Testdaten
        For i As Integer = 0 To 99
            lst.Add(New data With {.Daten = "Satz " & CStr(i), .satzposition = _
              i})
        Next i
 
        'Datenbindung
        bs.DataSource = lst
 
        dgv.AllowUserToAddRows = False
    End Sub
 
 
    Dim swapindex As Integer = -1
 
 
    Private Sub dgv_RowHeaderMouseClick(sender As Object, _
             e As System.Windows.Forms.DataGridViewCellMouseEventArgs) _
        Handles dgv.RowHeaderMouseClick
 
        'Rechtsclick auf den Rowheader markiert ein Item für den 
        ' Positions-Tausch
        'Rechtsclick auf ein weiteres Item führt den Tausch durch
        'Rechtsclick auf markiertes Item hebt Markierung auf
 
        If e.RowIndex = -1 Then
           If not swapindex = -1 Then 
              dgv.Rows(swapindex).DefaultCellStyle.BackColor = Color.White
              swapindex = -1        
           End If 
           Exit Sub
        end if
 
        If e.Button = MouseButtons.Right Then
            If swapindex = -1 Then
                'Erster Click Index merken
                swapindex = e.RowIndex
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = _
                Color.LightGreen
            ElseIf swapindex = e.RowIndex Then
                'Aufheben bei erneutem Click
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = Color.White
                swapindex = -1
            Else
                Dim dt1 As data = CType(bs(e.RowIndex), data)
                Dim dt2 As data = CType(bs(swapindex), data)
 
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = Color.White
                swapindex = -1
 
                'Satzpositionen tauschen
                Dim pos2 As Integer = dt2.satzposition
                dt2.satzposition = dt1.satzposition
                dt1.satzposition = pos2
 
                'Listenelemente nach Tausch neu sortieren
                lst.Sort()
            End If
        End If
    End Sub
End Class