Public Class frmDGVSwap2
 
    'Datenklasse mit Vergleichs-Schnittstelle für Sortieren
    Private Class data
        Public Property Daten As String
    End Class
 
    'Liste, Bindung und Control
    Dim lst As New List(Of Data)
    Dim bs As New BindingSource With {.RaiseListChangedEvents = True}
    Dim WithEvents dgv As New DataGridView With {.Parent = Me, .DataSource = bs}
 
 
    Private Sub frmDGVSwap_Load(sender As System.Object, _
                        e As System.EventArgs) Handles MyBase.Load
 
        'Testdaten
        For i As Integer = 0 To 99
            lst.Add(New data With {.Daten = "Satz " & CStr(i)})
        Next i
 
        'Datenbindung
        bs.DataSource = lst
 
        dgv.AllowUserToAddRows = False
    End Sub
 
 
    Dim swapindex As Integer = -1
 
    Private Sub dgv_RowHeaderMouseClick(sender As Object, _
                        e As _
                        System.Windows.Forms.DataGridViewCellMouseEventArgs) _
                    Handles dgv.RowHeaderMouseClick
 
        'Rechtsclick auf den Rowheader markiert ein Item für den 
        ' Positions-Tausch
        'Rechtsclick auf ein weiteres Item führt den Tausch durch
        'Rechtsclick auf markiertes Item hebt Markierung auf
 
        If e.RowIndex = -1 Then
            If Not swapindex = -1 Then
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = Color.White
                swapindex = -1
            End If
            Exit Sub
        End If
 
        If e.Button = MouseButtons.Right Then
            If swapindex = -1 Then
                'Erster Click Index merken
                swapindex = e.RowIndex
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = _
                  Color.LightGreen
            ElseIf swapindex = e.RowIndex Then
                'Aufheben bei erneutem Click
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = Color.White
                swapindex = -1
            Else
 
                'Referenzen auf Datensätze besorgen
                Dim dt1 As data = CType(bs(e.RowIndex), data)
                Dim dt2 As data = CType(bs(swapindex), data)
 
                bs.RemoveAt(e.RowIndex)
                bs.Insert(e.RowIndex, dt2)
 
                bs.RemoveAt(swapindex)
                bs.Insert(swapindex, dt1)
 
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = Color.White
                swapindex = -1
 
            End If
        End If
    End Sub
 
End Class