Public Class frmDGVSwap2
 
    'Datenklasse mit Vergleichs-Schnittstelle für Sortieren
    Private Class data
        Public Property Daten As String
        Public Property ForeColor As Color
        Public Property RowHeight As Integer
    End Class
 
    'Liste, Bindung und Control
    Dim lst As New List(Of Data)
 
    Dim bs As New BindingSource _
             With {.RaiseListChangedEvents = True}
 
    Dim WithEvents dgv As New DataGridView _
             With {.Parent = Me, .DataSource = bs}
 
 
    Private Sub frmDGVSwap_Load(sender As System.Object, _
                        e As System.EventArgs) Handles MyBase.Load
 
        'Testdaten
        Dim c As Color, h As Integer
        For i As Integer = 0 To 99
            If i Mod 3 = 0 Then c = Color.Red : h = 20
            If i Mod 3 = 1 Then c = Color.Blue : h = 25
            If i Mod 3 = 2 Then c = Color.Magenta : h = 30
            lst.Add(New data With {.Daten = "Satz " & CStr(i), _
                                   .ForeColor = c, .RowHeight = h})
        Next i
 
        'Datenbindung
        bs.DataSource = lst
 
        dgv.AllowUserToAddRows = False
 
    End Sub
 
 
    Dim swapindex As Integer = -1
 
    Private Sub dgv_CellPainting(sender As Object, _
        e As System.Windows.Forms.DataGridViewCellPaintingEventArgs) _
        Handles dgv.CellPainting
 
        If e.RowIndex = -1 Or e.ColumnIndex = -1 Then Exit Sub
 
        Dim dt As data = DirectCast(bs(e.RowIndex), data)
 
        'Die Gridspalte entsprechend den Angaben im Datensatz einrichten
        With dgv.Rows(e.RowIndex)
            .Cells(e.ColumnIndex).Style.ForeColor = dt.ForeColor
            .Height = dt.RowHeight
        End With
 
    End Sub
 
 
    Private Sub dgv_RowHeaderMouseClick(sender As Object, _
            e As System.Windows.Forms.DataGridViewCellMouseEventArgs) _
            Handles dgv.RowHeaderMouseClick
 
        'Rechtsclick auf den Rowheader markiert ein Item für den 
        ' Positions-Tausch
        'Rechtsclick auf ein weiteres Item führt den Tausch durch
        'Rechtsclick auf markiertes Item hebt Markierung auf
 
        If e.RowIndex = -1 Then
            If Not swapindex = -1 Then
                'Zeile neu zeichnen lassen
                dgv.InvalidateRow(swapindex)
                swapindex = -1
            End If
            Exit Sub
        End If
 
        If e.Button = MouseButtons.Right Then
            If swapindex = -1 Then
                'Erster Click: Index merken / Markierfarbe
                swapindex = e.RowIndex
                dgv.Rows(swapindex).DefaultCellStyle.BackColor = _
                  Color.LightGreen
            ElseIf swapindex = e.RowIndex Then
                'Aufheben der Markierung bei erneutem Click
                dgv.InvalidateRow(swapindex)
                swapindex = -1
            Else
 
                'Referenzen auf Datensätze besorgen
                Dim dt1 As data = CType(bs(e.RowIndex), data)
                Dim dt2 As data = CType(bs(swapindex), data)
 
                bs.RemoveAt(e.RowIndex)
                bs.Insert(e.RowIndex, dt2)
 
                bs.RemoveAt(swapindex)
                bs.Insert(swapindex, dt1)
 
                'getauschte Zeilen neu zeichnen lassen
                dgv.InvalidateRow(swapindex)
                dgv.InvalidateRow(e.RowIndex)
 
                swapindex = -1
            End If
        End If
    End Sub
 
End Class