Public Class frmKasseSub
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
    Dim txtProdukt As New TextBox With {.Parent = Me, .Width = 200}
    Dim txtPreis As New TextBox With {.Parent = Me, .Width = 200, .Left = 210}
 
    Public WriteOnly Property spalten() As DataColumn()
        'Übergabe der Spalten
        Set(value As DataColumn())
            dt.Clear()
            dt.Columns.Clear()
            For i As Integer = 0 To value.Length - 1
                dt.Columns.Add(value(i).ColumnName, value(i).DataType)
            Next i
 
            'Datenbindung
            bs.DataSource = dt
            txtProdukt.DataBindings.Add("Text", bs, value(0).ColumnName)
            txtPreis.DataBindings.Add("Text", bs, value(1).ColumnName)
        End Set
    End Property
 
 
    Public WriteOnly Property RowToAdd() As DataRow
        'Übergabe einer Datenzeile
        Set(value As DataRow)
            Dim nr As DataRow = dt.NewRow
            For i As Integer = 0 To dt.Columns.Count - 1
                nr(i) = value(i)
            Next i
            dt.Rows.Add(nr)
            bs.ResetBindings(False)
            bs.Position = bs.Count - 1
        End Set
    End Property
 
End Class
 
 
'Das Hauptformular ...
Public Class frmKasseMain
 
    Dim frmSub As New frmKasseSub 'unterg. Formular
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
    Dim WithEvents btn As New Button _
         With {.Parent = Me, .Text = "... in Liste"}
 
    Private Sub frmKasseMain_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        'Testdaten
        dt.Columns.Add("Produkt", GetType(String))
        dt.Columns.Add("Preis", GetType(Decimal))
 
        With dt.Rows
            .Add("Tür", 1245.5)
            .Add("Fenster", 745.29)
            .Add("Vorhang", 121.75)
        End With
 
        Dim dc(dt.Columns.Count - 1) As DataColumn
        dt.Columns.CopyTo(dc, 0)
 
        'Spaltenübergabe 
        frmSub.spalten = dc
        frmSub.Visible = True
 
    End Sub
 
 
    Private Sub btn_Click(sender As Object, _
         e As System.EventArgs) Handles btn.Click
 
        Dim number As Integer
        Dim react As String = InputBox _
          ("Datensatznummer angeben (1-" & dt.Rows.Count.ToString & ")")
        If Not Integer.TryParse(react, number) OrElse _
            (number < 1 Or number > dt.Rows.Count) Then
            MsgBox("Falsche eingabe") : Exit Sub
        End If
 
        'Datensatz ins untergeordnete Formular (dort anhängen)
        frmSub.RowToAdd = dt.Rows(number - 1)
 
    End Sub
End Class