Zitat:

Meine Frage: Gibt es eine Möglichkeit den Rtf-Text in Plain-Text zu konvertieren. Der Idealfall wäre natürlich, dass die Steuercodes innerhalb des Textes, wie Zeilenumbruch oder Farbe, erhalten bleiben.

Dim rtbox As New RichTextBox
rtbox.Rtf = "Rtf-Text"
Dim plain = rtbox.Text

Public Class frmRTF_Insert
 
    Dim rtb As New RichTextBox With _
         {.Parent = Me, .Width = 300, .Height = 300}
 
    Private Sub frmRTF_Insert_Load(sender As System.Object, _
                    e As System.EventArgs) Handles MyBase.Load
 
        Const placeholder As String = "<<Platzhalter>>"
 
        'Text des Dokument erstellen 
        rtb.Text = "Projektnr. 1234567" & vbCrLf & _
            "Einstufung: sehr wichtig - streng vertraulich" & vbCrLf & vbCrLf & _
            placeholder & vbCrLf & _
            "Für Rückfragen steht Ihnen jederzeit spatzimatzi zur Verfügung"
 
        SetColor("wichtig", Color.Red)
        SetColor("vertraulich", Color.Red)
        setfont("1234567", New Font("Arial", 12, FontStyle.Bold))
        setfont("spatzimatzi", New Font("Arial", 12, FontStyle.Underline))
 
 
        'Abfragen des Dokuments als String 
        Dim rtfdoc As String = rtb.Rtf
 
 
        'Einzufügender Text
        rtb.Text = "Das Projekt wird wegen eines RTF-Problems" & vbCrLf & _
            "nicht rechtzeitig abgeschlossen werden können"
 
        SetColor("nicht rechtzeitig", Color.Blue)
        setfont("RTF-Problems", _
        New Font(rtb.Font.Name, rtb.Font.Size, FontStyle.Underline Or _
        FontStyle.Bold))
 
 
        'Abfrage des einzufügenden Textes als String
        Dim rtfinsert As String = rtb.Rtf
 
 
        'Text einfügen 
        rtfdoc = rtfdoc.Replace(placeholder, rtfinsert)
 
 
        'Dokument incl Einfügung anzeigen
        rtb.Rtf = rtfdoc
 
    End Sub
 
    Private Sub SetColor(ByVal text As String, col As Color)
        With rtb
            .SelectionStart = rtb.Find(text)
            .SelectionLength = text.Length
            .SelectionColor = col
            .SelectionLength = 0
        End With
    End Sub
 
    Private Sub setfont(ByVal text As String, ByVal fnt As Font)
        With rtb
            .SelectionStart = rtb.Find(text)
            .SelectionLength = text.Length
            .SelectionFont = fnt
            .SelectionLength = 0
        End With
    End Sub
End Class