Public Class Class_Form1
    Inherits Windows.Forms.Form
 
    Dim WithEvents btn1 As New Button With _
        {.Parent = Me, .Text = "Process starten", .Width = 200}
    Dim txt1 As New TextBox With _
        {.Parent = Me, .Top = 50, .Width = 200}
 
    Dim WithEvents c1 As New Class_Class1
 
    Delegate Sub stringdel(ByVal str As String)
 
 
    Private Sub c1_ProcessInfo (sender As Object, _
        e As ProcessInfoEventargs) Handles c1.ProcessInfo
 
        Me.Invoke(New stringdel(AddressOf SetInfo), {e.Info})
    End Sub
 
 
    Private Sub SetInfo(ByVal str As String)
        txt1.Text = str
    End Sub
 
 
    Private Sub btn1_Click(sender As Object, _
        e As System.EventArgs) Handles btn1.Click
        c1.RunProcess()
    End Sub
End Class
 
 
Public Class ProcessInfoEventargs
    Inherits EventArgs
 
    Dim _info As String = ""
    Public ReadOnly Property Info As String
        Get
            Return _info
        End Get
    End Property
    Public Sub New(Info As String)
        _info = Info
    End Sub
End Class
 
 
Public Class Class_Class1
 
    Public Event ProcessInfo(ByVal sender As Object, _
        e As ProcessInfoEventargs)
 
    Public Sub RunProcess()
 
        Dim th As New Threading.Thread(AddressOf rx_thread)
        th.Start()
    End Sub
 
    Public Sub RX_THread()
        RaiseEvent ProcessInfo _
            (Me, New ProcessInfoEventargs("anzuzeigender Text"))
    End Sub
End Class