Imports System.Runtime.InteropServices
 
Public Class frmMausText
 
    Dim lblWindowText As New Label _
        With {.Parent = Me, .Width = 512}
 
    Dim WithEvents tim As New Timer _
        With {.Interval = 300}
 
 
    <DllImport("user32.dll", ExactSpelling:=True, SetLastError:=True)> _
    Public Shared Function GetCursorPos(ByRef lpPoint As POINTAPI) As _
    <MarshalAs(UnmanagedType.Bool)> Boolean
    End Function
 
 
    <StructLayout(Runtime.InteropServices.LayoutKind.Sequential)> _
    Public Structure POINTAPI
        Public X As Integer
        Public Y As Integer
 
        Public Sub New(ByVal X As Integer, ByVal Y As Integer)
            Me.X = X
            Me.Y = Y
        End Sub
    End Structure
 
 
    <DllImport("user32.dll")> _
    Public Shared Function WindowFromPoint( _
      ByVal xPoint As Integer, _
      ByVal yPoint As Integer) As System.IntPtr
    End Function
 
 
    <DllImport("user32.dll", EntryPoint:="SendMessage")> _
    Public Shared Function SendMessage(hWnd As IntPtr, _
               Msg As UInt32, wParam As Integer, _
               <Out()> lParam As System.Text.StringBuilder) As Integer
    End Function
 
 
    Private Const WM_GETTEXT As UInt32 = &HD
 
 
    Private Sub frmMausText_Load(sender As System.Object, _
                    e As System.EventArgs) Handles MyBase.Load
        Me.Width = 520
        tim.Enabled = True
    End Sub
 
 
    Private Sub tim_Timer() Handles tim.Tick
        Dim oPoint As POINTAPI
        Dim hWnd As System.IntPtr
        Dim TextLength As Integer
        Dim sWindowText As New System.Text.StringBuilder(512)
 
        lblWindowText.Text = String.Empty
 
        ' Mausposition ermitteln
        If GetCursorPos(oPoint) Then
 
            ' Fensterhandle des Controls 
            ' über dem sich der Mauszeiger befindet
            hWnd = WindowFromPoint(oPoint.X, oPoint.Y)
 
            If Not hWnd = IntPtr.Zero Then
                ' Fenstertext des Controls ermitteln
                TextLength = SendMessage(hWnd, WM_GETTEXT, 512, sWindowText)
 
                If TextLength > 0 Then
                    ' Control-Text in das Label schreiben
                    ' falls kein aktives Control --> 
                    ' Fenstertext wird geliefert
                    lblWindowText.Text = sWindowText.ToString
                End If
            End If
        End If
    End Sub
End Class