Imports Microsoft.VisualBasic
Imports System.Web.UI.WebControls
Imports System.Web.UI
 
Namespace EigeneControls
    Public Class MetaCtrl
        Inherits Control
 
        'Eine Property für das meta-Attribut "Name"
        Private _name As String = ""
        Public Property Name() As String
            Get
                Return _name
            End Get
            Set(ByVal value As String)
                _name = value
            End Set
        End Property
 
        'Eine Property für das meta-Attribut "Content"
        Private _content As String = ""
        Public Property Content() As String
            Get
                Return _content
            End Get
            Set(ByVal value As String)
                _content = value
            End Set
        End Property
 
        'Das HTML-Meta-Tag schreiben
        Protected Overrides Sub Render(ByVal wr As System.Web.UI.HtmlTextWriter)
            wr.WriteBeginTag("meta")
            wr.WriteAttribute("name", Me.Name)
            wr.WriteAttribute("content", Me.Content)
            wr.Write(HtmlTextWriter.SelfClosingTagEnd)
            wr.Flush()
            MyBase.Render(wr)
        End Sub
    End Class
End Namespace

Imports Microsoft.VisualBasic
Imports System.Collections.Generic
 
Public Class BasePage
    Inherits System.Web.UI.Page
 
    Protected Overrides Sub OnPreRender(ByVal e As System.EventArgs)
        Try
            'wenn keine Masterpage da ist, nix machen
            If Me.Master Is Nothing Then
                Return
            End If
 
            'Alle eigenen Meta-Controlsfinden
            Dim metas As List(Of EigeneControls.MetaCtrl)
            metas = FindAllMeta(Me)
            If metas.Count = 0 Then
                Return
            End If
 
            'Die Metacontrols von der Seite entfernen
            For Each meta As EigeneControls.MetaCtrl In metas
                meta.Parent.Controls.Remove(meta)
            Next
 
            'DieMetacontrols zum Head der Masterpage dazutun
            Dim mPage As MasterPage = CType(Me.Master, MasterPage)
            For Each ctrl As Control In mPage.Controls
                If TypeOf ctrl Is HtmlHead Then
                    For Each meta As EigeneControls.MetaCtrl In metas
                        ctrl.Controls.Add(meta)
                    Next
                    Exit For
                End If
            Next
        Catch ex As Exception
            Debug.WriteLine(ex.ToString)
        Finally
            MyBase.OnPreRender(e)
        End Try
    End Sub
 
    'Findet rekursiv alle Meta-Controls in der Seite
    Private Function FindAllMeta(ByVal startCtrl As Control) As List(Of _
      EigeneControls.MetaCtrl)
        Dim ret As New List(Of EigeneControls.MetaCtrl)
        If startCtrl.HasControls Then
            For Each subCtrl As Control In startCtrl.Controls
                If TypeOf subCtrl Is EigeneControls.MetaCtrl Then
                    ret.Add(CType(subCtrl, EigeneControls.MetaCtrl))
                End If
                If subCtrl.HasControls Then
                    Dim subList As List(Of EigeneControls.MetaCtrl) = _
                      FindAllMeta(subCtrl)
                    ret.AddRange(subList)
                End If
            Next
        End If
        Return ret
    End Function
End Class

<%@ Page Language="VB" MasterPageFile="~/MasterPage.master" _
  AutoEventWireup="false"
CodeFile="Default.aspx.vb" Inherits="_Default" title="Untitled Page" %>
<%@ Register Namespace="EigeneControls" TagPrefix="ec"  %>
<asp:Content ID="cpHdr" ContentPlaceHolderID="ContentPlaceHolder1" Runat="Server">
	<ec:MetaCtrl ID="meta1" runat="server" Name="keywords" Content="Keyword1" />
	Seite 1<br />
</asp:Content>

Partial Class _Default
    Inherits BasePage
 
End Class