'Erforderlicher Verweis
Imports System.Windows.Forms.DataVisualization
 
'Deklarationen
Dim dt As New DataTable
Dim cht As New Charting.Chart 
 
'einige Demodaten in einer Datatable erstellen
dt.Columns.Add("String", GetType(String))
dt.Columns.Add("Decimal", GetType(Decimal))
dt.Columns.Add("Double", GetType(Double))
For i As Integer = 1 To 20
   dt.Rows.Add("STR" & CInt(i), CDec(i Mod 3) / 2#, CDbl(i Mod 4) / 1.5#)
Next i
 
'=============================
'Demo-Chart
'=============================
 
'Chart an DataTable binden
cht.DataSource = dt
 
'Chart säubern
With cht
  .ChartAreas.Clear() : .Titles.Clear() 
  .Series.Clear() : .Legends.Clear()
End With
 
'Namen für ChartElemente vergeben
Dim SeriesName As String = "MeineDecimalSerie"
Dim SeriesName2 As String = "MeineDoubleSerie"
Dim AreaName As String = "MeineArea"
Dim TitelName As String = "Title1"  '!!!!!!!!!
Dim LegendName As String = "Meine Legende"
 
'Area erstellen und die Y-Achse einrichten
cht.ChartAreas.Add(AreaName)
With cht.ChartAreas(AreaName).AxisY
   .Maximum = 2 : .Minimum = -0.25 : .Interval = 0.25
   .MajorGrid.Enabled = True
   .MinorGrid.Enabled = False
End With
 
'Chart-Titel erstellen und einrichten
cht.Titles.Add(TitelName)
With cht.Titles(TitelName)
    .Text = "Der Titel des Chart"
    .Docking = Charting.Docking.Bottom
    .Font = New Drawing.Font("Arial", 12, Drawing.FontStyle.Italic)
End With
 
'Legende erstellen und einrichten
cht.Legends.Add(LegendName)
With cht.Legends(LegendName)
   .LegendStyle = Charting.LegendStyle.Table
   .TableStyle = Charting.LegendTableStyle.Auto
   .Title = "Spalten aus einer DataTable"
   .Docking = Charting.Docking.Right
   .BorderWidth = 2
   .BorderColor = Drawing.Color.Green
End With
 
'Datenserie anfügen, einrichten und binden
cht.Series.Add(SeriesName)
With cht.Series(SeriesName)
    .ChartArea = AreaName
    .IsXValueIndexed = True
    .XValueMember = "String"   'an Datenspalte binden
    .YValueMembers = "Decimal"
    .ChartType = Charting.SeriesChartType.Line
    .IsVisibleInLegend = True
    .MarkerStyle = Charting.MarkerStyle.Square
    .MarkerSize = 10
End With
 
'Zweite Datenserie anfügen, einrichten und binden
cht.Series.Add(SeriesName2)
With cht.Series(SeriesName2)
     .ChartArea = AreaName
     .IsXValueIndexed = True
     .XValueMember = "String"  'an Datenspalte binden  
     .YValueMembers = "Double"
     .ChartType = Charting.SeriesChartType.Line
     .IsVisibleInLegend = True
     .IsValueShownAsLabel = False
     .MarkerStyle = Charting.MarkerStyle.Circle
     .MarkerColor = Drawing.Color.Red
     .MarkerSize = 10
End With