Dim File, strComputer, eRet, processtxt, runallways, run, entry, Output
 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & _
  "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set ofso = createobject("Scripting.FileSystemObject")
 
' Whitelist: Prozesse, die nicht überwacht werden sollen
File = ".\whitelist.txt"
run = 0
runallways = 1
 
' ProcessArrays zur Berechnung des Deltas zwischen zwei Messungen
Dim ProcessArray()
Redim ProcessArray(0)
Dim TempArray()
Redim TempArray(0)
 
' Zur Speicherung der Meldungen im Ereignislog
Set objShell = Wscript.CreateObject("Wscript.Shell")
 
If ofso.fileexists(File) Then
 
	' Whitelist-Einträge einladen	
	Set processtxt = ofso.OpenTextFile(File, 1)
	RA =  processtxt.ReadAll
	GetLine = processtxt.Line   
	processtxt.Close
	counter = 0
 
	sqlAdd = " WHERE Name != " & """" & "Check" & """" 
	Set processtxt = ofso.OpenTextFile(File, 1)
	Do Until counter = GetLine
		sqlAdd	= sqlAdd & " AND Name != " & """" & processtxt.ReadLine & """"
		counter = counter + 1
	Loop	
	sql = "Select * from Win32_Process " & sqlAdd	
 
	' Beginne mit der Prozessüberwachung (Endlosschleife! Überwachung beenden mit 
' Killen von wscript.exe im Task-Manager.)
	Do Until run = 1
 
		' Prozesse lesen
		Set colProcessList = objWMIService.ExecQuery(sql)
 
		procCount = 0
		' Alle laufenden Prozesse durchgehen
		For Each objProcess In colProcessList
			' Nachschauen, ob der Prozess neu gestartet wurde
			processAlreadyRunning = False
			For Each entry In ProcessArray
				If objProcess.Name = entry Then
					processAlreadyRunning = True
				End If
			Next
			If processAlreadyRunning = False Then
				objShell.LogEvent 0, objProcess.Name & " was started..."
			End If
 
			' Bei zu kleinem Array, erweitern...
			procCount = procCount + 1
			If Ubound(TempArray) < procCount Then Redim Preserve TempArray(procCount)
  			TempArray(procCount) = objProcess.Name
		Next
 
		' Nachschauen, ob Prozesse seit dem letzten Durchlauf beendet wurden
		For Each entry In ProcessArray
			processStillRunning = False
			' Nachschauen, ob der alte Prozess noch läuft
			For Each oldEntry In TempArray
				If oldEntry = entry Then processStillRunning = True
			Next
			If processStillRunning = False Then
				objShell.LogEvent 0, entry & " has been ended..."
			End If
		Next
 
		' Neues Prozessarray wird zum alten
		ReDim ProcessArray( Ubound(TempArray) )
		For i = 1 To UBound(TempArray)
			ProcessArray(i) = TempArray(i)
		Next
 
		' Warte einige (Milli)sekunden bis zum neuen Durchlauf (je nach 
' Prozessorstärke und Wunsch anpassen)
		WScript.sleep 100
 
		If runallways = 0 Then
			run = run + 1
		End If
 
	Loop
 
Else
	wscript.echo "whitelist.txt nicht gefunden"
End If