Private Function FindMyFile(ByVal sFolder As String, _
  ByVal sFile As String) As String
 
  On Error Resume Next
  Dim sCurrent As String
  Dim cFolders As New Collection
  Dim i As Integer
  sFile = LCase(sFile)
  If Right(sFolder, 1) <> "\" Then sFolder = sFolder & "\"
  ' Ordner durchsuchen
  sCurrent = Dir(sFolder & "*.*", _
    vbArchive + vbHidden + vbReadOnly + vbSystem + vbDirectory)
  While sCurrent <> ""
    If sCurrent <> "." And sCurrent <> ".." Then
      If GetAttr(sFolder & sCurrent) And vbDirectory Then
        cFolders.Add sCurrent
      Else
        If LCase(sCurrent) = sFile Then
          FindMyFile = sFolder & sFile
          Exit Function
        End If
      End If
    End If
    sCurrent = Dir()
  Wend
  ' Unterordner durchgehen
  For i = 1 To cFolders.Count
    FindMyFile = FindMyFile(sFolder & cFolders(i), sFile)
    If FindMyFile <> "" Then Exit For
  Next i
End Function

MsgBox FindMyFile("C:\", "meine.exe")

Web: http://www.vbtricks.de.vu/

VBTricks.de.vu. Meine Webseite zu VB und anderen Programmiersprachen. Verschiedene fortgeschrittene OCXe und komplette Projekte sind im Sourcecode verf?gbar.