' Access-Tabelle nach Excel exportieren
Public Function ExportXLS(ByVal sDBFile As String, _
   ByVal sTable As String, _
   ByVal sExcelFile As String, _
   Optional ByVal sWorksheet As String = "WorkSheet1", _
   Optional ByVal sPassword As String = "", _
   Optional ByVal sExcelVersion As String = "8.0", _
   Optional ByVal bDeleteIfExists As Boolean = True) As Boolean
 
   Dim oConnDB As ADODB.Connection
 
   ' Fehlerbehandlung aktivieren
   On Error GoTo ErrHandler
 
   Set oConnDB = New ADODB.Connection
   With oConnDB
      .CursorLocation = adUseClient
      .Provider = "Microsoft.Jet.OLEDB.4.0"
      .Properties("Data Source") = sDBFile
      .Properties("Persist Security Info") = False
      If sPassword <> "" Then
         .Properties("Jet OLEDB:Database Password") = sPassword
      End If
      .Open
   End With
 
 
   ' GGf. Excel-Datei vorher löschen, falls vorhanden
   If Len(Dir(sExcelFile)) > 0 And bDeleteIfExists Then Kill sExcelFile
 
   ' alle Datensätze der Access-Tabelle in die Excel-Tabelle exportieren
   oConnDB.Execute "SELECT * INTO [Excel " & sExcelVersion & ";" & _
      "DATABASE=" & sExcelFile & "]." & "[" & sWorksheet & "] " & _
      "FROM " & "[" & sTable & "]"
 
   ' Datenbank schließen und Objekt zerstören
   oConnDB.Close
   Set oConnDB = Nothing
   On Error GoTo 0
   ExportXLS = True
   Exit Function
 
ErrHandler:
   MsgBox "Fehler beim Export der Tabelle nach Excel" & vbCrLf & _
      CStr(Err.Number) & " " & Err.Description
 
   ' Datenbank-Objekt schließen und   zerstören
   If Not oConnDB Is Nothing Then
      oConnDB.Close
      Set oConnDB = Nothing
   End If
End Function

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control