Private Type EintragType
    Dateiname As String * 50 ' das ist bei Dir die Spalte 1
    ImFeld As Boolean ' das ist bei Dir die Spalte 4
    BenutzerID As Long ' das ist bei Dir die Spalte 18
    Farbe As Long ' das ist bei Dir die Spalte 19
End Type
Private Farbe(3) As Long
 
Private Sub Form_Load()
Dim Eintrag As EintragType
Dim FF1 As Integer
Dim i As Long
 
Farbe(0) = &HFFFFC0
Farbe(1) = &HFF00&
Farbe(2) = &HFFFF&
Farbe(3) = &HFF&
 
Rem dieser Teil dient nur zum Erzeugen einer Datei
Rem mit 1000 Zeilen und 4 Spalten mit zufälligen Werten
Rem diese müssen später natürlich mit Deinen Werten gefüllt werden
Rem die Datei wird anstelle Deiner Excel-Datei verwendet
FF1 = FreeFile
Open "C:\Probe" For Random As FF1 Len = Len(Eintrag)
For i = 1 To 1000
    Eintrag.Dateiname = "Datei" & i
    Eintrag.ImFeld = Not Eintrag.ImFeld
    Eintrag.BenutzerID = Int((4 * Rnd) + 1) 'zufällige BenutzerID (1 bis 4)
    Eintrag.Farbe = Farbe(Int((3 * Rnd) + 1)) 'zufällige Farbe (1 bis 3)
    Put FF1, i, Eintrag 'Eintrag speichern
Next
Close FF1
 
Rem alle Dateien ins TreeView mit Farbe 0
For i = 1 To 1000
    TreeView1.Nodes.Add(, , , "Datei" & i).BackColor = Farbe(0)
Next
End Sub
 
 
Private Sub Command1_Click()
Dim Knoten As Node
Dim Eintrag As EintragType
Dim FF1 As Integer
Dim i As Long
Dim BenutzerID As Long
BenutzerID = CLng(InputBox("Geben Sie die BenutzerID (1 bis 4) ein.", _
  "BenutzerID", 1))
 
MsgBox "Jetzt kommt das, was bei Dir so lange dauert.", vbOKOnly, "Achtung"
Rem alle Nodes auf Farbe 0 setzen
For Each Knoten In TreeView1.Nodes
    Knoten.BackColor = Farbe(0)
Next
Rem Datei durchsuchen und Farben entsprechend setzen
FF1 = FreeFile
Open "C:\Probe" For Random As FF1 Len = Len(Eintrag)
For i = 1 To LOF(FF1) / Len(Eintrag)
    Get FF1, i, Eintrag 'Eintrag lesen
    If Eintrag.ImFeld Then
        If Eintrag.BenutzerID = BenutzerID Then
            For Each Knoten In TreeView1.Nodes
                If Knoten.Text = Trim$(Eintrag.Dateiname) Then
                    Knoten.BackColor = Eintrag.Farbe
                    Exit For
                End If
            Next
        End If
    End If
Next
Close FF1
MsgBox "Ich bin fertig.", vbOKOnly, "Das war es"
End Sub