' Controls: 1 Picturebox, 1 Commandbutton
Option Explicit
 
Private Declare Function TransparentBlt& Lib "msimg32.dll" (ByVal hdcDest&, _
  ByVal nXOriginDest&, ByVal nYOriginDest&, ByVal nWidthDest&, ByVal _
  nHeightDest&, _
  ByVal hDCSrc&, ByVal nXOriginSrc&, ByVal nYOriginSrc&, ByVal nWidthSrc&, _
  ByVal nHeightSrc&, ByVal crTransparent&)
Private Declare Function CreateCompatibleDC& Lib "gdi32.dll" (ByVal hdc&)
Private Declare Function SelectObject& Lib "gdi32.dll" (ByVal hdc&, ByVal _
  hObject&)
Private Declare Function DeleteDC& Lib "gdi32.dll" (ByVal hdc&)
 
Private Sub Command1_Click()
 
Dim TmpPic As StdPicture, P1hdc&, P1OldPic&, Breite&, Höhe&, Maskenfarbe&
 
Me.ScaleMode = vbPixels
Maskenfarbe = RGB(255, 0, 0) ' <- Maskenfarbe hier einsetzen
Set TmpPic = LoadPicture("C:\EinBild.bmp") ' <- Dateipfad hier einsetzen
P1hdc = CreateCompatibleDC(Me.hdc)
P1OldPic = SelectObject(P1hdc, TmpPic.Handle)
With Picture1
  .ScaleMode = vbPixels
  Breite = CLng(.ScaleX(TmpPic.Width, vbHimetric))
  Höhe = CLng(.ScaleY(TmpPic.Height, vbHimetric))
  .BackColor = RGB(255, 255, 255) ' <- neue Himtergrundfarbe hier einsetzen
  .Move .Left, .Top, Breite + 4 * .BorderStyle, Höhe + 4 * .BorderStyle
  .AutoRedraw = True
  Call TransparentBlt(.hdc, 0, 0, Breite, Höhe, P1hdc, 0, 0, Breite, Höhe, _
    Maskenfarbe)
  Set .Picture = .Image
  .Cls
  .AutoRedraw = False
End With
Call SelectObject(P1hdc, P1OldPic)
Call DeleteDC(P1hdc)
Set TmpPic = LoadPicture()
 
End Sub

Gruss,

Zardoz