Option Explicit
Private CtPos() As Single, FrmBreite As Single, FrmHöhe As Single
 
 
Private Sub Form_Activate()
 
Dim Ctr As Object, C As Integer
 
FrmBreite = Me.ScaleWidth
FrmHöhe = Me.ScaleHeight
C = 0
For Each Ctr In Me.Controls
 
  '1. wenn keine Zusatzsteuerelemente verwendet:
  If Not (TypeOf Ctr Is Timer Or TypeOf Ctr Is Menu) Then
 
  '2. wenn ImageList verwendet:
  'If Not (TypeOf Ctr Is Timer Or TypeOf Ctr Is Menu Or TypeOf Ctr Is 
  ' ImageList) Then
 
  '3. wenn CommonDialog verwendet:
  'If Not (TypeOf Ctr Is Timer Or TypeOf Ctr Is Menu Or TypeOf Ctr Is 
  ' CommonDialog) Then
 
  '4. wenn ImageList und CommonDialog verwendet:
  'If Not (TypeOf Ctr Is Timer Or TypeOf Ctr Is Menu Or TypeOf Ctr Is ImageList 
  ' Or TypeOf Ctr Is CommonDialog) Then
 
    ReDim Preserve CtPos(3, C)
    With Ctr
    If TypeOf Ctr Is Line Then
      CtPos(0, C) = .X1
      CtPos(1, C) = .Y1
      CtPos(2, C) = .X2
      CtPos(3, C) = .Y2
    Else
      CtPos(0, C) = .Left
      CtPos(1, C) = .Top
      CtPos(2, C) = .Width
      CtPos(3, C) = .Height
    End If
    .Tag = C
    End With
    C = C + 1
  End If
Next Ctr
 
End Sub
 
Private Sub Form_Resize()
 
Dim Ctr As Object, Fkt1 As Single, Fkt2 As Single, Ix As Integer
 
If FrmBreite > 0 Then
  Fkt1 = Me.ScaleWidth / FrmBreite
  Fkt2 = Me.ScaleHeight / FrmHöhe
  For Each Ctr In Me.Controls
    If Not (TypeOf Ctr Is Timer Or TypeOf Ctr Is Menu) Then
      With Ctr
      If .Tag <> "" Then
        Ix = .Tag
        If TypeOf Ctr Is Line Then
          .X1 = CtPos(0, Ix) * Fkt1
          .Y1 = CtPos(1, Ix) * Fkt2
          .X2 = CtPos(2, Ix) * Fkt1
          .Y2 = CtPos(3, Ix) * Fkt2
        Else
          .Move CtPos(0, Ix) * Fkt1, CtPos(1, Ix) * Fkt2, CtPos(2, Ix) * Fkt1
          If Not (TypeOf Ctr Is DriveListBox Or TypeOf Ctr Is ComboBox) Then
            .Height = CtPos(3, Ix) * Fkt2
          End If
        End If
      End If
      End With
    End If
  Next Ctr
End If
 
End Sub