Private Sub cmdOpen_Click()
  ' wird im "CommonDialog" auf "Abbrechen" geklickt,
  ' wird (wenn CancelError = True ist) ein Laufzeitfehler ausgelöst.
  Dim F As Integer
  Dim AllText As String
  Dim LineOfText As String
 
  On Error Resume Next
  With CommonDialog1
    .CancelError = True
    ' Filter setzen - hier wird festgelegt, mit welchem Format
    ' eine Datei geöffnet wird.
    .Filter = "Textdateien (*.txt)|*.txt"
 
    ' Dialogfeld Öffnen anzeigen
    .ShowOpen
    If .FileName <> "" Then
      F = FreeFile
      Open .FileName For Input As #F
      ' Zeilen aus Textdatei einlesen und in Variable AllText speichern
      Do Until EOF(F)
        Line Input #F, LineOfText
        AllText = AllText & LineOfText & vbCrLf
      Loop
      Close #F
 
      ' Inhalt der Variable AllText im Textfeld ausgeben
      Text1.Text = AllText
    End If
  End With
End Sub

Private Sub cmdSave_Click()
  ' wird im "CommonDialog" auf "Abbrechen" geklickt,
  ' wird (wenn CancelError = True ist) ein Laufzeitfehler ausgelöst.
  Dim F As Integer
 
  On Error Resume Next
  With CommonDialog1
    .CancelError = True
    ' Hinweis, falls Datei bereits vorhanden
    ' weitere Flags-Eigenschaften finden Sie in der MSDN
    .Flags = cdlOFNOverwritePrompt
 
    ' Filter setzen - hier wird festgelegt, unter welchem 
    ' Format eine Datei gespeichert wird.
    .Filter = "Textdateien (*.txt)|*.txt"
 
    ' Dialogfeld Speichern anzeigen
    .ShowSave
    If .FileName <> "" Then
      F = FreeFile
      Open .FileName For Output As #F
      Print #F, Text1.Text
      Close #F
    End If
  End With
End Sub