' Default Printer
Private Const HWND_BROADCAST As Long = &HFFFF&
Private Const WM_WININICHANGE As Long = &H1A
 
Private Declare Function WriteProfileString Lib "kernel32" _
   Alias "WriteProfileStringA" _
  (ByVal lpszSection As String, _
   ByVal lpszKeyName As String, _
   ByVal lpszString As String) As Long
 
Private Declare Function SendMessage Lib "user32" _
   Alias "SendMessageA" _
  (ByVal hWnd As Long, _
   ByVal wMsg As Long, _
   ByVal wParam As Long, _
   lParam As Any) As Long
 
Public Sub SetDefaultPrinterNT(ByVal sPrinterName As String)
  Dim sDeviceLine As String
  Dim oPrinter    As Printer
 
  For Each oPrinter In Printers
    If oPrinter.DeviceName = sPrinterName Then
      sDeviceLine = oPrinter.DeviceName & "," & oPrinter.DriverName & "," & _
        oPrinter.Port
      Exit For
    End If
  Next oPrinter
  ' Neuen Printer in die Win.ini schreiben
  Call WriteProfileString("windows", "Device", sDeviceLine)
 
  ' Gott und die Welt vom neuen Drucker berichten
  Call SendMessage(HWND_BROADCAST, WM_WININICHANGE, 0, ByVal "windows")
End Sub