'Anwerdungname, bitte vollen Pfad angeben!
strCommand = "Notepad.exe" 
'******************************************************************************
' ****************************************
Set objWMIService = GetObject( _
  "winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set objStartup = objWMIService.Get("Win32_ProcessStartup")
Set objConfig = objStartup.SpawnInstance_
objConfig.ShowWindow = 1
Set objProcess = objWMIService.Get("Win32_Process")
intReturn = objProcess.Create (strCommand, Null, objConfig, intProcessID)
Set objWMIService = nothing
Set objStartup = nothing
Set objConfig = nothing
Set objProcess = nothing
If intReturn <> 0 Then
    Wscript.Echo "Process could not be created." & _
        vbNewLine & "Command line: " & strCommand & _
        vbNewLine & "Return value: " & intReturn
Else
      intSituation = true
      While intSituation
            intSituation = false
            'Prüfintervall, ob Prozess noch vorhanden ist ==> 1 Sekunde == 1000
            WScript.Sleep 1000
            Set colProcesses = GetObject( _
              "winmgmts:{impersonationLevel=impersonate}!\\" _
                  & ".\root\cimv2").ExecQuery("Select * from Win32_Process")
            For Each objProc in colProcesses
                  If objProc.ProcessId = intProcessID Then
                        intSituation = True
                  End If
            Next
            Set colProcesses = nothing
      Wend
      Set WshShell = WScript.CreateObject("WScript.Shell")
      'Hier wird abgemeldet ;-)
      WshShell.run "Shutdown /l"
End If