Option Explicit
 
'Datentyp für Registrierung eines Zahlenübergangs
Private Type Wechsel
    vorher As Integer
    nachher As Integer
    anzahl As Integer
End Type
 
'Register der Übergangshäufigkeiten    
Private register() As Wechsel
 
'Verwaltung des Registers    
Private Sub RegistriereWechsel(ByVal vorher As Integer, _
                               ByVal nachher As Integer)
 
   Dim i As Integer, gefunden As Boolean
 
   gefunden = False
   For i = 1 To UBound(register)
      With register(i)
         If .vorher = vorher And .nachher = nachher Then
             'vorhandener Wechsel / Zählen
             .anzahl = .anzahl + 1
             gefunden = True: Exit For
         End If
      End With
   Next i
 
   If Not gefunden Then
       'neuer Wechsel
       i = UBound(register) + 1
       ReDim Preserve register(i)
       Dim w As Wechsel
       w.vorher = vorher
       w.nachher = nachher
       w.anzahl = 1
       register(i) = w
  End If
 
 
End Sub
 
 
Private Function NumLen(ByVal number As Integer, _
                       minlen As Integer) As String
 
    'Formatierung der Ausgabe
 
    NumLen = CStr(number)
    While Len(NumLen) < minlen
        NumLen = " " & NumLen
    Wend
 
End Function
 
 
Private Sub Form_Load()
    ReDim register(0)
 
    Dim ik%, ak%, i%, z%, w%
    Dim number1%, number2%
 
    ik = FreeFile
    Open "C:\daten\suchen-neu.txt" For Input As #ik
 
    'Datei lesen
    Input #ik, number1
 
    While Not EOF(ik)
        Input #ik, number2
        If Not number1 = number2 Then
           RegistriereWechsel number1, number2
           w = w + 1
        End If
        number1 = number2
        z = z + 1
    Wend
    Close #ik
 
    ak = FreeFile
 
    'Ausgabe füllen
    Open "C:\daten\zahlenübergänge.txt" For Output As #ak
 
    Print #ak, "Anzahl Zahlen: "; z
    Print #ak, "Anzahl Übergänge: "; w
    Print #ak, ""
 
    For i = 1 To UBound(register)
        With register(i)
            Print #ak, "Nach "; NumLen(.vorher, 3); " folgt "; _
            NumLen(.nachher, 3); " = "; NumLen(.anzahl, 3)
        End With
    Next i
 
    Close #ak
 
End Sub