Option Explicit
 
'Mindestgröße der Arbeitsfläche
Private Const MinWidth As Integer = 10000
Private Const MinHeight As Integer = 10000
 
 
 
Private Sub Form_Resize()
  Dim hVis As Boolean
  Dim vHis As Boolean
 
  If Me.WindowState <> 1 Then
    ' nur wenn Form nicht minimiert ist
 
    'Resize der Arbeitsfläche 
    If Me.ScaleWidth >= MinWidth Then
       Picture1.Width = Me.ScaleWidth - VScroll1.Width - 200
    Else
       Picture1.Width = MinWidth - VScroll1.Width - 200
    End If
 
    If Me.ScaleHeight >= MinHeight Then
       Picture1.Height = Me.ScaleHeight - HScroll1.Height - 200
    Else
       Picture1.Height = MinHeight - HScroll1.Height - 200
    End If
 
    ' wenn die Form kleiner als die PictureBox ist
    ' entsprechend vertik. bzw. horiz. ScrollBars anzeigen
    VScroll1.Visible = (Picture1.Height > Me.ScaleHeight)
    HScroll1.Visible = (Picture1.Width > Me.ScaleWidth)
    Picture2.BorderStyle = 0
    Picture2.Visible = HScroll1.Visible Or VScroll1.Visible
 
    ' Breite des horizontalen Scrollbalkens
    HScroll1.Width = Me.ScaleWidth
 
    ' Höhe des vertikalen Scrollbalkens
    VScroll1.Height = Me.ScaleHeight
 
    ' Scrollbalken positionieren
    HScroll1.Left = 0
    HScroll1.Top = Me.ScaleHeight - HScroll1.Height
    VScroll1.Left = Me.ScaleWidth - VScroll1.Width
    VScroll1.Top = 0
 
    Picture2.Left = Me.ScaleWidth - VScroll1.Width
    Picture2.Top = Me.ScaleHeight - HScroll1.Height
    HScroll1.Width = Picture2.Left
    VScroll1.Height = Picture2.Top
 
    ' Min/Max-Eigenschaften aktualisieren
    VScroll1.Max = (Picture1.Height - Me.ScaleHeight) + _
      HScroll1.Height
    HScroll1.Max = (Picture1.Width - Me.ScaleWidth) + _
      VScroll1.Width
  End If
 
End Sub
 
 
Private Sub HScroll1_Change()
  Picture1.Left = -HScroll1.Value
End Sub
 
Private Sub HScroll1_Scroll()
  Picture1.Left = -HScroll1.Value
End Sub
 
Private Sub VScroll1_Change()
  Picture1.Top = -VScroll1.Value
End Sub
 
Private Sub VScroll1_Scroll()
  Picture1.Top = -VScroll1.Value
End Sub
 
 
Private Sub Picture1_Resize()
 
    'Neuanordnung des Controls auf der Arbeitsfläche 
    Command1.Top = Picture1.Height - Command1.Height - 200
    Command1.Left = Picture1.Width - Command1.Width - 200
 
End Sub