<code>
Private Declare Function GetWindowRect Lib "user32" _
   (ByVal hWnd As Long, lpRect As RECT) As Long
 
Private Declare Function CreateRectRgnIndirect Lib "gdi32" _
   (lpRect As RECT) As Long
 
Private Declare Function RectInRegion Lib "gdi32" _
   (ByVal hRgn As Long, lpRect As RECT) As Long
 
Private Declare Function SetRect Lib "user32" _
   (lpRect As RECT, ByVal X1 As Long, _
    ByVal Y1 As Long, ByVal X2 As Long, _
    ByVal Y2 As Long) As Long
 
Private Declare Function DeleteObject Lib "gdi32" _
   (ByVal hObject As Long) As Long
 
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type
 
Private tmpWall As Object
Private tmpTarget As Object
Private tmpWallID As Long
Private tmpColl As Boolean
 
'Objekt Wall
Public Property Get Wall() As Object
   Set Wall = tmpWall
End Property
Public Property Set Wall(ByRef oWall As Object)
   Set tmpWall = oWall
End Property
 
'Objekt Target
Public Property Get Target() As Object
   Set Target = tmpTarget
End Property
Public Property Set Target(ByRef oTarget As Object)
   Set tmpTarget = oTarget
End Property
 
Public Sub MoveTarget()
   Dim tRect As RECT
   Dim wRect As RECT
   Dim hRgn As Long
   tmpColl = False
 
   GetWindowRect tmpTarget.hWnd, tRect
   GetWindowRect tmpWall.hWnd, wRect
 
   hRgn = CreateRectRgnIndirect(wRect)
 
   If RectInRegion(hRgn, tRect) <> 0 Then
      tmpColl = True
   End If
 
   DeleteObject hRgn
End Sub
 
Public Property Get WallID() As Long
    WallID = tmpWallID
End Property
 
Public Property Let WallID(ByVal vNewValue As Long)
    tmpWallID = vNewValue
End Property
 
Public Property Get Collision() As Boolean
   Collision = tmpColl
End Property</code>