Option Explicit
 
Private Type FormSize
    w As Long
    h As Long
End Type
 
Private Type ControlPosition
    l As Long
    t As Long
    w As Long
    h As Long
End Type
 
Private m_FormSize As FormSize
Private m_ControlPosition() As ControlPosition
 
Private Sub Form_Load()
 
    Dim lngIndex As Long
 
    ReDim m_ControlPosition(Me.Controls.Count - 1)
 
    Dim Ctrl As Control
    For Each Ctrl In Me.Controls
        With m_ControlPosition(lngIndex)
            .l = Ctrl.Left
            .t = Ctrl.Top
            .w = Ctrl.Width
            .h = Ctrl.Height
        End With
        lngIndex = lngIndex + 1
    Next
 
    With m_FormSize
        .w = Me.Width
        .h = Me.Height
    End With
End Sub
 
Private Sub Form_Resize()
 
    Dim lngIndex As Long
    Dim dblScaleX As Double
    Dim dblScaleY As Double
 
    dblScaleX = Me.Width / m_FormSize.w
    dblScaleY = Me.Height / m_FormSize.h
 
    Dim Ctrl As Control
    For Each Ctrl In Me.Controls
 
        Call Ctrl.Move(m_ControlPosition(lngIndex).l * dblScaleX, _
          m_ControlPosition(lngIndex).t * dblScaleY, _
                       m_ControlPosition(lngIndex).w * dblScaleX, _
                       m_ControlPosition(lngIndex).h * dblScaleY)
 
        lngIndex = lngIndex + 1
    Next
 
End Sub

Mit freundlichen Grüßen
-Franky-