Private Declare Function Shell_NotifyIcon Lib "shell32.dll" _
 Alias "Shell_NotifyIconA" _
 (ByVal dwMessage As Long, _
 lpData As NOTIFYICONDATA) As Long
 
Private Type NOTIFYICONDATA
  cbSize As Long
  hwnd As Long
  uID As Long
  uFlags As Long
  uCallbackMessage As Long
  hIcon As Long
  szTip As String * 64
End Type
 
Private Const NIF_ICON = &H2
Private Const NIF_MESSAGE = &H1
Private Const NIF_TIP = &H4
Private Const NIM_ADD = &H0
Private Const NIM_DELETE = &H2
Private Const NIM_MODIFY = &H1
 
Private IC As NOTIFYICONDATA
 
Private Sub Form_Initialize()
   mnupop.Visible = False
End Sub
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, x As Single, y _
  As Single)
 
  If Hex(x) = "1E3C" Then
     'rechte Maustaste gedrückt
     'PopupMenu anzeigen
     PopupMenu mnupop
  End If
 
End Sub
 
Private Sub cmdFrmHidde_Click()
  Form1.Visible = False
  With IC
    .cbSize = Len(IC)
    .hwnd = Me.hwnd 'Nachrichten-Fenster
    .uID = 2& 'unveränderlich
    .uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
    .uCallbackMessage = &H200 'Auswertung in MouseMove
    .hIcon = Form1.Icon 'anzuzeigendes Icon=Icon der Form
    .szTip = Form1.Caption + vbNullChar
  End With
  Shell_NotifyIcon NIM_ADD, IC
 
End Sub
 
Private Sub mnupopVisible_Click()
   'TrayIcon entfernen
   Shell_NotifyIcon NIM_DELETE, IC
   Form1.Visible = True
End Sub