'IN modRegisterHotkey
Private Declare Function WaitMessage Lib "user32" () _
                                                As Long
 
Public Declare Function RegisterHotKey Lib "user32" _
                                                (ByVal hwnd As Long, _
                                                ByVal id As Long, _
                                                ByVal fsModifiers As Long, _
                                                ByVal vk As Long) _
                                                As Long
 
Private Declare Function UnregisterHotKey Lib "user32" _
                                                (ByVal hwnd As Long, _
                                                ByVal id As Long) _
                                                As Long
 
Private Declare Function PeekMessage Lib "user32" _
                                                Alias "PeekMessageA" _
                                                (lpMsg As MSG, _
                                                ByVal hwnd As Long, _
                                                ByVal wMsgFilterMin As Long, _
                                                ByVal wMsgFilterMax As Long, _
                                                ByVal wRemoveMsg As Long) _
                                                As Long
 
Private Type POINTAPI
    x           As Long
    y           As Long
End Type
 
Private Type MSG
    hwnd        As Long
    message     As Long
    wParam      As Long
    lParam      As Long
    time        As Long
    pt          As POINTAPI
End Type
 
Public Enum KeyControl
    PM_REMOVE = &H1
    MOD_ALT = &H1
    MOD_CONTROL = &H2
    WM_HOTKEY = &H312
End Enum
 
Private blMessage As Boolean
 
Public Sub WaitForAction(ByVal hwnd As Long, ByVal frm As Form, ByVal nIndex As _
  Long)
    Select Case nIndex
        Case 1
            Dim mse As MSG
            Do While Not blMessage
                WaitMessage
                If PeekMessage(mse, hwnd, WM_HOTKEY, WM_HOTKEY, PM_REMOVE) Then
                    'Aktion die ueber den vordef. Hotkey ausgefuehrt werden 
                    ' soll.
                    'In diesem Beispiel wird das Programm hier beendet.
                    End
                    '
                End If
                DoEvents
            Loop
        Case 2
            blMessage = True
            Call UnregisterHotKey(hwnd, &HBFFF&)
    End Select
End Sub
 
'IN Form1
'Beispiel : Hotkey registrieren.
 
Private Sub Form_Load()
    Dim lRet As Long
    lRet = RegisterHotKey(Me.hwnd, &HBFFF&, MOD_ALT, vbKeyPrint)
    Me.Show
    WaitForAction Me.hwnd, Form1, 1
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    WaitForAction Me.hwnd, Form1, 2
    Set Form1 = Nothing
    End
End Sub
 
Private Sub Command1_Click()
    Call Form_Unload(True)
End Sub