Option Explicit
 
' zunächst die benötigten API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" (ByVal hwnd As Long, _
  ByVal wMsg As Long, ByVal wParam As Long, _
  ByVal lParam As Any) As Long
 
Private Const EM_GETLINE = &HC4
Private Const EM_GETLINECOUNT = &HBA

' Inhalt einer MultiLine-TextBox zeilenweise
' in ein String-Array übertragen
Public Function Text2Array(TextBox As TextBox) As Variant
 
  Dim I As Long
  Dim lngLineCount As Long
  Dim lngLineLength As Long
  Dim strLine As String
  Dim nCount As Long
  ReDim sArray(0) As String
 
  ' zunächst die Anzahl der Zeilen ermitteln
  lngLineCount = SendMessage(TextBox.hwnd, _
    EM_GETLINECOUNT, 0, 0&)
 
  If lngLineCount >= 0 Then
    ReDim sArray(lngLineCount)
 
    ' jetzt die einzelnen Zeilen ermitteln
    For I = 0 To lngLineCount - 1
      strLine = Space$(1024)
 
      lngLineLength = SendMessage(TextBox.hwnd, _
        EM_GETLINE, I, strLine)
 
      ' Zeile ins Array schreiben
      sArray(I) = Left$(strLine, lngLineLength)
    Next I
  End If
 
  Text2Array = sArray
End Function

Private Sub Command1_Click()
  Dim arsLines() As String
  Dim I As Integer
 
  Text1.Text = "Hallo mein name ist qs. asfhjhasf - asfasf as-asfasf -" & _
    "asfasffasf -as   --asf   -as sfaf"
 
  arsLines = Text2Array(Text1)
 
  ' Zeilen auf PictureBox schreiben
  For I = 0 To UBound(arsLines) - 1
    Picture1.Print arsLines(I)
  Next
End Sub

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de