'Lege 2 Pictureboxen in die Form.
Option Explicit
Private Farbe As Long
 
Private Sub Form_Load()
  Dim i As Integer, j As Integer, Feld As Integer
 
  Me.ScaleMode = vbPixels
  Me.WindowState = vbMaximized
  With Picture1
  .ScaleMode = vbPixels
  .BackColor = vbBlack
  .Move 10, 10, 300, 300
  .AutoRedraw = True
  .Cls
  End With
  With Picture2
  .ScaleMode = vbPixels
  .Move 320, 10, 105, 105
  .AutoRedraw = True
  .Cls
  .FillStyle = 0
  Feld = 25
  For i = 0 To 3
    For j = 0 To 3
      .FillColor = QBColor(4 * i + j)
      Picture2.Line (Feld * i, Feld * j)-Step(Feld, Feld), vbBlack, B
    Next j
  Next i
  End With
  Farbe = vbWhite
End Sub
 
Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As _
  Single, Y As Single)
  Picture1.CurrentX = X
  Picture1.CurrentY = Y
End Sub
 
Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As _
  Single, Y As Single)
  If Button = vbLeftButton Then
    Picture1.Line -(X, Y), Farbe
  End If
End Sub
 
Private Sub Picture2_MouseDown(Button As Integer, Shift As Integer, X As _
  Single, Y As Single)
  If Button = vbLeftButton Then
    Farbe = Picture2.Point(X, Y)
  ElseIf Button = vbRightButton Then
    Picture1.BackColor = Picture2.Point(X, Y)
  End If
End Sub