Private Declare Function PtInRect Lib "user32" _
  (lpRect As RECT, ByVal X As Long, _
    ByVal Y As Long) As Long
 
Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
 
Private rct As RECT
 
Private Sub Form_Initialize()
   SetRect
End Sub
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y _
  As Single)
    Static xx As Long
    Dim ix As Long
    Dim iy As Long
 
    ix = X / Screen.TwipsPerPixelX
    iy = Y / Screen.TwipsPerPixelY
    If PtInRect(rct, ix, iy) Then
       MousePointer = 9
    Else
       MousePointer = 0
    End If
    If MousePointer = 9 And Button = 1 Then
       If ix < xx Then
          List1.Width = List1.Width - Screen.TwipsPerPixelX
          List2.Left = List2.Left - Screen.TwipsPerPixelX
          List2.Width = List2.Width + Screen.TwipsPerPixelX
       ElseIf ix > xx Then
          List1.Width = List1.Width + Screen.TwipsPerPixelX
          List2.Left = List2.Left + Screen.TwipsPerPixelX
          List2.Width = List2.Width - Screen.TwipsPerPixelX
       End If
    End If
    SetRect
    xx = ix
End Sub
 
Private Sub SetRect()
   With rct
      .Left = (List1.Left + List1.Width) / Screen.TwipsPerPixelX
      .Right = List2.Left / Screen.TwipsPerPixelX
      .Top = List1.Top / Screen.TwipsPerPixelY
      .Bottom = (List1.Top + List1.Height) / Screen.TwipsPerPixelY
   End With
End Sub
 
Private Sub List1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y _
  As Single)
   MousePointer = 0
End Sub
 
Private Sub List2_MouseMove(Button As Integer, Shift As Integer, X As Single, Y _
  As Single)
   MousePointer = 0
End Sub