'Benötigt werden: 2 * Picturebox, 1 * Label
Option Explicit
 
Private Sub Form_Load()
 
Dim i%, j%, Linien%, C%(2), P1%, P2%, P3%, P4%, SW&, SH&, Farbe&
 
Linien = 30
Me.WindowState = vbMaximized
Me.ScaleMode = vbPixels
Randomize
Label1.Move 520, 10
With Picture1
.BackColor = vbBlack
.ScaleMode = vbPixels
.Move 10, 10, 500, 300
.AutoRedraw = True
.Cls
SW = .ScaleWidth
SH = .ScaleHeight
With Picture2
.Visible = False
.BorderStyle = Picture1.BorderStyle
.BackColor = vbWhite
.DrawWidth = 5 'Empfindlichkeit
.ScaleMode = vbPixels
.Move 0, 0, Picture1.Width, Picture1.Height
.AutoRedraw = True
.Cls
End With
For i = 0 To Linien - 1
  Do
    For j = 0 To 2
      C(j) = Choose(1 + Rnd * 3, 0, 128, 255)
    Next j
    Farbe = RGB(C(0), C(1), C(2))
  Loop While Farbe = 0
  Do
    P1 = SW * Rnd
    P2 = SH * Rnd
    P3 = SW * Rnd
    P4 = SH * Rnd
  Loop While Abs(P1 - P3) < 30 And Abs(P2 - P4) < 30
  Picture1.Line (P1, P2)-(P3, P4), Farbe
  Picture2.Line (P1, P2)-(P3, P4), i
Next i
End With
 
End Sub
 
Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As _
  Single, Y As Single)
 
Dim LIx&
 
LIx = Picture2.Point(X, Y)
If LIx = vbWhite Then
  Label1.Caption = "leer"
Else
  Label1.Caption = "Linie " & LIx
End If
 
End Sub