Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal _
  hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Type ItemRect
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
 
Private Const LB_ITEMFROMPOINT = &H1A9
Private Const LB_GETITEMRECT = &H198
Private Const HIGH = &H10000
 
Private Sub File1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y _
  As Single)
    Dim sName As String
    Dim sPath As String
    Dim I As Integer
    Dim th As Integer
    Dim lParam As Long
    Dim ret As Long
    Dim iRect As ItemRect
    Dim PosY As Long
    Dim PosX As Long
 
    Debug.Print File1.ListIndex
 
    PosX = CLng(X / Screen.TwipsPerPixelX)
    PosY = CLng(Y / Screen.TwipsPerPixelY)
    lParam = PosX + HIGH * PosY
 
    ret = SendMessage(File1.hwnd, LB_ITEMFROMPOINT, 0, ByVal lParam)
    ret = SendMessage(File1.hwnd, LB_GETITEMRECT, ret, iRect)
 
    If Not (((PosY >= iRect.Top) And (PosY <= iRect.Bottom)) And ((PosX _
      >= iRect.Left) And (PosX <= iRect.Right))) Then
        Exit Sub
    End If
 
    With File1
        If Button = vbRightButton And .ListIndex >= 0 Then
            sName = InputBox("Neuer Name:", "Umbenennen", .List(.ListIndex))
            If sName <> "" And sName <> .List(.ListIndex) Then
                sPath = .Path & IIf(Right$(.Path, 1) <> "\", "\", "")
                Name sPath & .List(.ListIndex) As sPath & sName
                .Refresh
                For I = 0 To .ListCount - 1
                    If .List(I) = sName Then
                        .ListIndex = I
                        Exit For
                    End If
                Next I
            End If
        End If
    End With
End Sub

Gru? Michi aus Hannover

1 + 1 = 3 f?r hinreichend gro?e 1