Public Function rtf_Load(rtfControl As Control, _
  ByVal sFile As String, _
  Optional cProgress As Object = Nothing) As Boolean
 
  ' Dokument laden (Text oder RTF)
  Dim F As Integer
  Dim lSize As Long
  Dim lCurPos As Long
  Dim lBytes As Long
  Dim sContent As String
  Dim iProz As Integer
 
  ' Falls Datei nicht existiert, Funktion beenden
  If Dir$(sFile) = "" Then
    rtf_Load = False
    Exit Function
  End If
 
  If Not cProgress Is Nothing Then  
    ' RichTextBox ausblenden und ProgressBar einblenden
    With rtfControl
      .Text = ""
      .Visible = False
      ShowProgress cProgress, 0, 0, 0
      cProgress.Visible = True
      DoEvents
 
      ' maximale Blockgröße
      Const lBlock = 16384
 
      F = FreeFile
      Open sFile For Binary As #F
 
      ' Datei blockweise kopieren
      lSize = LOF(F): lCurPos = 0
      Do While lCurPos < lSize
        lBytes = lBlock
        If lCurPos + lBytes > lSize Then _
          lBytes = lSize - lCurPos
 
        ' Lesen
        sContent = Space$(lBytes)
        Get #F, , sContent
 
        ' Und ab ins RTF-Control
        .SelText = sContent
 
        ' Status aktualisiern
        lCurPos = lCurPos + lBytes
        iProz = Int(lCurPos / lSize * 100 + 0.5)
 
        ' Fortschrift...
        ShowProgress cProgress, iProz, 0, 100
        DoEvents
      Loop
      Close #F
 
      ' RichTextBox einblenden und ProgressBar ausblenden
      .Visible = True
      .SelStart = 0
      cProgress.Visible = False
    End With
 
  Else
    ' herkömmliche Methode "LoadFile" verwenden
    rtfControl.LoadFile sFile
  End If
 
  rtf_Load = True
End Function

Cu David
--------------------------------------------
ist eine geniale Erfindung

Q-lympics ist geil