Private Sub Form_Load()
 
  On Error GoTo Err_Load
 
  ' Timer initialisieren
  tmrMain.Interval = 60000
  tmrMain.Enabled = False
 
  Dim strDisplayName As String
  Dim bStarted As Boolean
 
  ' LogFile-Klasse erstellen
  Set cLog = New clsLog
 
  ' Dateiname für das LogFile festlegen
  cLog.sFileName = App.Path & "\Log.txt"
 
  Set cLog.NTService = NTService1
 
  strDisplayName = NTService1.DisplayName
 
  If Command = "-install" Then
    NTService1.Interactive = True
 
    ' Installiert den Dienst
    If NTService1.Install Then
      MsgBox strDisplayName & " erfolgreich installiert"
    Else
      MsgBox strDisplayName & " konnte nicht " & _
        "installiert werden"
    End If
    End
 
  ElseIf Command = "-uninstall" Then
    If NTService1.Uninstall Then
      MsgBox strDisplayName & " erfolgreich deinstalliert"
    Else
      MsgBox strDisplayName & " konnte nicht " & _
        "deinstalliert werden"
    End If
    End
 
  ElseIf Command = "-debug" Then
    NTService1.Debug = True
 
  ElseIf Command <> "" Then
    MsgBox "Invalid command option"
    End
  End If
 
  NTService1.ControlsAccepted = svcCtrlPauseContinue
 
  NTService1.StartService
  Exit Sub
 
Err_Load:
  If NTService1.Interactive Then
    MsgBox "[" & Err.Number & "] " & Err.Description
    End
  Else
    cLog.NewLog "[" & Err.Number & "] " & Err.Description
  End If
End Sub