' Die Funktion isCurrentVersion gibt 1 zurück,
' wenn das Programm auf dem neusten Stand ist,
' 0 wenn dieses veraltet ist oder 2 wenn ein
' Fehler aufgetreten ist
Public Function isCurrentVersion() As Integer
  Dim sVersion As String ' komplette Versionsnummer
  Dim nMajor As Long     ' Hauptversionsnummer
  Dim nMinor As Long     ' Subversionsnummer
  Dim nRevision As Long  ' Revisionsnummer
 
  ' Konfigurieren des Inet-Controls
  With Inet1
    .AccessType = icDirect ' Direkte Verbindung
    .Protocol = icHTTP     ' HTTP-Protokoll verwenden
 
    ' Inhalt der Versionsdatei in Varibale speichern!
    sVersion = .OpenURL(sURL & LCase$(App.ProductName) & ".version", _
      icString)
 
    If Len(sVersion) > 50 Or Len(sVersion) = 0 Then
      ' Fehler! Evtl. konnte die Datei auf dem Server
      ' nicht gefunden werden!
      isCurrentVersion = 2
    Else
      ' Ggf. abschließenden Zeilenumbruch entfernen
      If InStr(sVersion, Chr$(13)) > 0 Then _
        sVersion = Left$(sVersion, InStr(sVersion, Chr$(13)) - 1)
 
      ' Versionsteile extrahieren
      nMajor = Val(Left$(sVersion, InStr(sVersion, ".") - 1))
      nMinor = Val(Mid$(sVersion, InStr(sVersion, ".") + 1))
      nRevision = Val(Right$(sVersion, InStr(sVersion, ".") + 2))
 
      ' Prüfen!
      isCurrentVersion = IIf((App.Major < nMajor) Or _
        (App.Major = nMajor And App.Minor < nMinor) Or _
        (App.Major = nMajor And App.Minor = nMinor And App.Revision < _
        nRevision), 0, 1)
    End If
  End With
End Function