Option Explicit
 
 
' Auf der Form befinden sich:
' 1x CommandButton    'cmdStart'   mit Caption 'Ziehung'
' 6x Label            'Label1' mit Indexe von 1-6
 
 
Private Sub cmdStart_Click()
Dim bFound  As Boolean
Dim i       As Integer
Dim j       As Integer
Dim iValue  As Integer
Dim aiArr() As Integer
 
  ReDim aiArr(0)
  ' 6 Zahlen ziehen
  For i = 1 To 6
    Do
      Call Randomize(Timer)
      iValue = CInt(Rnd() * 49 + 1)
      bFound = False
      ' Array durchgehen und bei doppeltem Eintrag neue Zufallszahl
      For j = 1 To UBound(aiArr)
        If iValue = aiArr(j) Then
          bFound = True
          Exit For
        End If
      Next j
      If Not bFound Then Exit Do
    Loop
    ' Zahl in Array eintragen
    ReDim Preserve aiArr(UBound(aiArr) + 1)
    aiArr(UBound(aiArr)) = iValue
  Next i
 
  ' Array sortieren
  Call QuickSort(aiArr, 1)
 
  ' Ausgabe in die Labels
  For i = 1 To UBound(aiArr)
    Label1(i).Caption = aiArr(i)
  Next i
 
End Sub
 
 
Public Sub QuickSort(vSort As Variant, Optional ByVal lngStart As Variant, _
  Optional ByVal lngEnd As Variant)
 
  ' Wird die Bereichsgrenze nicht angegeben,
  ' so wird das gesamte Array sortiert
 
  If IsMissing(lngStart) Then lngStart = LBound(vSort)
  If IsMissing(lngEnd) Then lngEnd = UBound(vSort)
 
  Dim i As Long
  Dim j As Long
  Dim h As Variant
  Dim x As Variant
 
  i = lngStart: j = lngEnd
  x = vSort((lngStart + lngEnd) / 2)
 
  ' Array aufteilen
  Do
 
    While (vSort(i) < x): i = i + 1: Wend
    While (vSort(j) > x): j = j - 1: Wend
 
    If (i <= j) Then
      ' Wertepaare miteinander tauschen
      h = vSort(i)
      vSort(i) = vSort(j)
      vSort(j) = h
      i = i + 1: j = j - 1
    End If
  Loop Until (i > j)
 
  ' Rekursion (Funktion ruft sich selbst auf)
  If (lngStart < j) Then QuickSort vSort, lngStart, j
  If (i < lngEnd) Then QuickSort vSort, i, lngEnd
 
End Sub