'Nur Zahlen, die Backtaste, Punkt, Komma und "-"(Minus) werden
'anerkannt. Punkt und Komma nur einmal. "-" nur am Anfang.
'Hierbei wird bei eventueller Markierung der Textbox ein Komma/"-"
'zugelassen, obwohl dieses evtl. bereits vorhanden ist. Sonst wäre
'die TextBox bei Selektierung für diese Zeichen blockiert.
'Bei Eingabe eines Punkts wird dieser zum Komma gemacht.
 
Sub NurZahl(Textfeld As TextBox, KeyAscii As Integer)
With Textfeld
 Select Case KeyAscii 'Übergebener Asciicode
'----------------------------------------------------------------
  Case 8, 48 To 57 'Backtaste, Tasten 0 bis 9
   KeyAscii = KeyAscii
'----------------------------------------------------------------
  Case 45 'Taste "-"
   If .SelStart = 0 Then 'Nur wenn Cursor am Anfang steht
     If Left(.Text, 1) = "-" And .SelLength = Len(.Text) _
     Then 'Minus-Zeichen bereits da, aber Text ist markiert
      KeyAscii = KeyAscii '- zulassen
     ElseIf Left(.Text, 1) = "-" Then  'Minus-Zeichen ist bereits da
      KeyAscii = 0 '- nicht zulassen
     End If
   Else 'Wenn Cursor nicht am Anfang steht
    KeyAscii = 0 '- nicht zulassen
   End If
'-----------------------------------------------------------------
  Case 44, 46 'Tasten Komma, Punkt
   Select Case InStr(1, .Text, ",")
    Case Is > 0 'Wenn Komma bereits da ist, kann kein
                'zweites eingegeben werden(KeyAscii=0)
                'es sei denn, der Text ist selektiert.
     If .SelLength = Len(.Text) Then
      KeyAscii = KeyAscii
     Else
      KeyAscii = 0
     End If
    Case Else 'Wenn nicht wird Punkt zu Komma gemacht.
     KeyAscii = 44
   End Select
'-----------------------------------------------------------------
  Case Else  'Alle anderen Zeichen
   KeyAscii = 0 '- nicht zulassen
 End Select
End With
End Sub

Private Sub txtPreis_KeyPress(KeyAscii As Integer)
   NurZahl txtPreis, KeyAscii
End Sub

Gru? aus dem Norden
manyki