Public Class FontComboBox
  Inherits ComboBox
 
  Public Sub New()
 
    ' alle verfügbaren Schriften auflisten
    With Me.Items
      For Each oFont As FontFamily In FontFamily.Families
        .Add(oFont.Name)
      Next
    End With
 
    ' Wir möchten uns um die Ausgabe der
    ' Listen-Einträge selbst kümmern
    Me.DrawMode = DrawMode.OwnerDrawFixed
 
  End Sub
 
  Private Sub FontComboBox_DrawItem(ByVal sender As Object, ByVal e As _
    System.Windows.Forms.DrawItemEventArgs) Handles Me.DrawItem
 
    ' ComboBox-Eintrag (Schriftname)
    Dim sItem As String = Me.Items(e.Index)
 
    Dim oFont As Font
 
    ' Neues Schrift-Objekt erzeugen und verfügbare Styles berücksichtigen
    Dim oFamily As New FontFamily(sItem)
    If oFamily.IsStyleAvailable(FontStyle.Regular) Then
      oFont = New Font(sItem, Me.Font.Size, FontStyle.Regular)
    ElseIf oFamily.IsStyleAvailable(FontStyle.Italic) Then
      oFont = New Font(sItem, Me.Font.Size, FontStyle.Italic)
    ElseIf oFamily.IsStyleAvailable(FontStyle.Bold) Then
      oFont = New Font(sItem, Me.Font.Size, FontStyle.Bold)
    ElseIf oFamily.IsStyleAvailable(FontStyle.Underline) Then
      oFont = New Font(sItem, Me.Font.Size, FontStyle.Underline)
    Else
      oFont = New Font(sItem, Me.Font.Size, FontStyle.Strikeout)
    End If
 
    ' Brush für Textfarbe
    Dim oBrush As Brush = New SolidBrush(e.ForeColor)
 
    ' Hintergrund
    e.DrawBackground()
 
    ' Text (Schriftname) ausgeben
    e.Graphics.DrawString(sItem, oFont, oBrush, e.Bounds.X, e.Bounds.Y)
 
    ' Aufräumen
    oBrush.Dispose()
 
  End Sub
End Class

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de