Public Sub Start()

Dim sf, df As Integer

Dim Buffer() As Byte

Dim BufSize As Long

Dim Cntr As Long

Dim OPD As Long

  BufSize = CLng(frmOptions.cbCopyBufferSize.Text) * 1024

  ReDim Buffer(0 To BufSize - 1) As Byte

  IsPaused = False

  StartTime = Now

  Resumed = Resumed + 1

  sf = FreeFile

  Open SourceFile For Binary As sf

  Seek sf, BytesDone + 1

  df = FreeFile

  Open DestinationFile For Binary As df

  Seek df, BytesDone + 1

  OPD = PercentageDone

  While Not EOF(sf) And Not IsPaused

    Get sf, , Buffer

    If (BytesDone + BufSize) > SourceFileSize Then

      BufSize = SourceFileSize - BytesDone

      ReDim Preserve Buffer(0 To BufSize - 1) As Byte

      Put df, , Buffer

      BytesDone = BytesDone + BufSize

    Else

      Put df, , Buffer

      BytesDone = BytesDone + BufSize

    End If

    If PercentageDone <> OPD Then RaiseEvent OnPercentageDoneChange

    OPD = PercentageDone

    DoEvents

  Wend

  Close (sf): Close (df)

  If BytesDone = SourceFileSize Then

    RaiseEvent OnCopyFinished

  ElseIf IsPaused Then

    RaiseEvent OnPause

  Else

    RaiseEvent OnAbort

  End If

End Sub