Option Explicit
 
Private Sub Command1_Click()
  Dim V As Variant, I As Long
 
  On Error Resume Next
 
  ' Prozessor-ID's
  V = ReadWMIData("ProcessorId", "Win32_Processor")
  For I = LBound(V) To UBound(V)
    MsgBox "ID Prozessor " & CStr(I + 1) & ": " & V(I)
  Next I
 
End Sub
 
' ermittelt die Daten aus WMI
Public Function ReadWMIData(ByVal sField As String, _
  ByVal sTable As String) As Variant
  On Error Resume Next
 
  Dim objWMI As Object
  Dim objQuery As Object
  Dim objProperty As Object
  Dim objItem As Object
  Dim V As Variant
  Dim S As String
 
  sField = UCase(sField)
 
  S = ""
  Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
  Set objQuery = objWMI.ExecQuery( _
    "Select " & sField & " from " & sTable)
 
  If Not objQuery Is Nothing Then
 
    For Each objProperty In objQuery
 
      If Not objProperty Is Nothing Then
 
        For Each objItem In objProperty.Properties_
 
          If Not objItem Is Nothing Then
            If (UCase(objItem.Name) = sField) And (IsArray( _
              objItem.Value) = False) And (IsNull(objItem.Value) = False) Then
              If S <> "" Then S = S & "|"
              S = S & Trim(CStr(objItem.Value))
            End If
          End If
 
        Next objItem
 
      End If
 
    Next objProperty
 
  End If
 
  Set objItem = Nothing
  Set objProperty = Nothing
  Set objQuery = Nothing
  Set objWMI = Nothing
 
  V = Split(S, "|")
  ReadWMIData = V
End Function

Viel Spass,
R@lf