Private Sub WSock_DataArrival(ByVal BytesTotal As Long)
  Dim GotData as String, F As Integer, TimeLeft As Long
 
  WSock.GetData GotData
 
  'Header abfangen?
  If DItem.ServerInfo Is Nothing Then
    Set DItem.ServerInfo = ResponseHeader(GotData)
    If DItem.ServerInfo Is Nothing Then
      WSock_Error 1, "Unbekanntes Headerformat", 0, DItem.Source, "", 0, True
      Exit Sub  'Es wurde kein Header runtergeladen
    End If
 
    DItem.BytesDown = DItem.ServerInfo.BytesDown 'falls resumed wurde
 
    RaiseEvent GotHeader(DItem.ServerInfo) 'Event auslösen
 
    If DItem Is Nothing Then Exit Sub 'Kann vorkommen, wenn innerhalb des 
    ' GotHeader - Ereignisses der Download beendet wurde
    If CancelAttempt Then Exit Sub 'Wegen Serverantwort Versuch abbrechen?
    If GotData = "" Then Exit Sub 'Es wurde nur der Header ausgewertet
  End If
 
 
  DItem.BytesDown = DItem.BytesDown + BytesTotal
 
  'Daten in Datei speichern
  If DItem.Aim = "" Then
    If LCase(DItem.ServerInfo.FileDesc) <> "text" Then
      WSock_Error 1, "No text file", 0, DItem.Source, "", 0, False
      Exit Sub
    End If
    'Daten in String speichern
    DItem.Text = DItem.Text & GotData
  Else
    'Daten auf der Festplatte speichern
    F = FreeFile
    Open DItem.Aim For Binary Lock Read Write As #F
      Put #F, DItem.BytesDown - BytesTotal + 1, GotData
    Close #F
  End If
 
  'Für die DownloadRate
  TimeLeft = (Timer - DItem.ServerInfo.StartTime)
  If TimeLeft = 0 Then TimeLeft = 1
  RaiseEvent Progress(DItem.BytesDown, DItem.ServerInfo.BytesTotal, ( _
    DItem.BytesDown - DItem.ServerInfo.BytesDown) / TimeLeft, BytesTotal)
End Sub