Private Function DLG_Printer(ByVal ParentHwnd As Long, ByVal flags As Long, _
                     ByRef FromPage As Long, ByRef ToPage As Long, _
                     ByRef MinPage As Long, ByRef MaxPage As Long, _
                     ByRef PrinterDC As Long, ByRef PrintToFile As Boolean, _
                     ByRef NumberOfCopies As Long, ByRef PrintOnlySelection As _
                     Boolean, _
                     ByRef PageString As String, ByRef PrintSorted As Boolean) _
                     As Long
  Dim pd As tPRINTDLG, r As Long
  With pd
    .lStructSize = Len(pd)
    .hwndOwner = ParentHwnd
    .nCopies = NumberOfCopies
    .nFromPage = FromPage
    .nToPage = ToPage
    .nMaxPage = MaxPage
    .nMinPage = MinPage
    flags = flags Or PD_RETURNDC
    If ParentHwnd = 0 Then flags = flags And Not PD_SHOWHELP
    .flags = flags
  End With
  r = PrintDlg(pd)
  If r Then
    With pd
      FromPage = .nFromPage
      ToPage = .nToPage
      MaxPage = .nMaxPage
      MinPage = .nMinPage
      PrinterDC = .hDC
      Printer.hDC = PrinterDC
      NumberOfCopies = .nCopies
      PageString = "" & .nMinPage & "-" & .nMaxPage
      If (.flags And PD_PAGENUMS) Then PageString = "" & .nFromPage & "-" & _
        .nToPage
      PrintToFile = ((.flags And PD_PRINTTOFILE) <> 0)
      PrintOnlySelection = ((.flags And PD_SELECTION) <> 0)
      PrintSorted = ((.flags And PD_COLLATE) <> 0)
      If PrintOnlySelection Then PageString = ""
    End With
  End If
  DLG_Printer = r
End Function