Private Sub CopyNodeProperties(ByRef Source As Node, ByRef Target As Node)
On Error Resume Next
Target.BackColor = Source.BackColor
Target.Bold = Source.Bold
Target.Checked = Source.Checked
Target.Expanded = Source.Expanded
Target.ExpandedImage = Source.ExpandedImage
Target.ForeColor = Source.ForeColor
Target.Image = Source.Image
Target.SelectedImage = Source.SelectedImage
Target.Sorted = Source.Sorted
Target.Tag = Source.Tag
Target.Visible = Source.Visible
End Sub
 
Private Sub CopyTreeViewHelper(ByRef Source As Node, ByRef Target As Node, _
  ByRef TargetTreeView As TreeView)
On Error Resume Next
Dim CurNode As Node, NewNode As Node
Set CurNode = Source.Child
While Not CurNode Is Nothing
    Set NewNode = TargetTreeView.Nodes.Add(Target.Index, tvwChild, CurNode.Key, _
      CurNode.Text)
    CopyNodeProperties CurNode, NewNode
    If CurNode.Children > 0 Then
        CopyTreeViewHelper CurNode, NewNode, TargetTreeView
    End If
    Set CurNode = CurNode.Next
Wend
End Sub
 
Private Function CopyTreeView(ByRef Source As TreeView, ByRef Target As _
  TreeView) As Boolean
On Error Resume Next
Dim CurNode As Node, NewNode As Node
If Source.Nodes.Count > 0 Then
    Target.Nodes.Clear
    Set CurNode = Source.Nodes(1)
    While Not CurNode Is Nothing
        Set NewNode = Target.Nodes.Add(, , CurNode.Key, CurNode.Text)
        CopyNodeProperties CurNode, NewNode
        If CurNode.Children > 0 Then
            CopyTreeViewHelper CurNode, NewNode, Target
        End If
        Set CurNode = CurNode.Next
    Wend
    CopyTreeView = True
Else
    CopyTreeView = False
End If
End Function

CopyTreeView lvSource, lvTarget

Web: http://www.vbtricks.de.vu/

VBTricks.de.vu. Meine Webseite zu VB und anderen Programmiersprachen. Verschiedene fortgeschrittene OCXe und komplette Projekte sind im Sourcecode verf?gbar.