'''''''''''''''''''''''''''''''''''''''''''''''''
'CaptureWindow
' - Captures any portion of a Window.
'hWndSrc
' - Handle to the Window to be captured.
' LeftSrc, TopSrc, WidthSrc, HeightSrc
' - Specify the portion of the window to capture.
' - Dimensions need to be specified in pixels.
'Returns
' - Returns a Picture object containing a bitmap of the specified
'   portion of the window that was captured.
'''''''''''''''''''''''''''''''''''''''''''''''''
Function CaptureWindow(ByVal hWndSrc As Long, ByVal LeftSrc As Long, ByVal _
  TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc As Long) As Picture
  Dim I As Integer, Pcnt As Integer
  Dim hDCSrc As Long, hDCMem As Long
  Dim hBmp As Long, hBmpPrev As Long
  Dim ret As Long
  Dim Zeile As String
 
  hDCSrc = GetWindowDC(hWndSrc)  ' Get device context for entire window.
 
  ' Create a memory device context for the memory DC.
  hDCMem = CreateCompatibleDC(hDCSrc)
  ' Create a bitmap and place it in the memory DC.
  hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
  hBmpPrev = SelectObject(hDCMem, hBmp)
 
  ' Copy the on-screen image into the memory DC.
  ret = BitBlt(hDCMem, 0, 0, WidthSrc, HeightSrc, hDCSrc, LeftSrc, TopSrc, _
    vbSrcCopy)
 
  ' Remove the new copy of the on-screen image.
  hBmp = SelectObject(hDCMem, hBmpPrev)
 
  ' Release the device context resources back to the system.
  ret = DeleteDC(hDCMem)
  ret = ReleaseDC(hWndSrc, hDCSrc)
 
  ' Call CreateBitmapPicture to create a picture object from the
  ' bitmap and palette handles. Then return the resulting picture object.
  Set CaptureWindow = CreateBitmapPicture(hBmp, 0)
End Function